source: git/configure.ac @ cdb5c7f

stereo-2025
Last change on this file since cdb5c7f was 1ddd621, checked in by Olly Betts <olly@…>, 4 months ago

Update for 1.4.17

  • Property mode set to 100644
File size: 13.8 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.4.17], [https://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2025 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_CANONICAL_HOST
64
65dnl Checks for programs.
66AC_PROG_CC
67AC_PROG_CPP
68
69AC_PROG_CXX
70AC_PROG_CXXCPP
71
72dnl Probe for any options needed to enable C++11 support.
73AX_CXX_COMPILE_STDCXX_11
74
75AM_PROG_CC_C_O
76
77AC_LANG([C])
78
79AC_EXEEXT
80AC_OBJEXT
81
82mswindows=no
83macos=no
84case $host_os in
85darwin*) macos=yes ;;
86*mingw*|*cygwin*|windows*) mswindows=yes ;;
87esac
88
89AC_C_BIGENDIAN
90
91AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
92AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
93
94AC_CHECK_LIB(m, sqrt)
95
96dnl x86 has excess precision issues with 387 FP instructions, which are
97dnl avoided by using SSE instructions instead.  By default we require SSE2
98dnl which for Intel means a Pentium 4 which was launched in 2000; Pentium
99dnl 3 was finally discontinued in 2007.
100AC_ARG_ENABLE([sse],
101[AS_HELP_STRING([--disable-sse],
102                [disable use of SSE FP instructions on x86])]
103[AS_HELP_STRING([[--enable-sse[=sse|sse2]]],
104                [set which SSE FP instructions to use on x86 (default: sse2)])],
105  [case ${enableval} in
106    sse|sse2|yes|no) ;;
107    *) AC_MSG_ERROR([bad value ${enableval} for --enable-sse or --disable-sse]) ;;
108  esac],
109  [enable_sse=yes])
110
111AC_MSG_CHECKING([whether to use SSE instructions on x86])
112case $host_cpu in
113  i*86)
114    if test "$enable_sse" = no ; then
115      AC_MSG_RESULT([no - WARNING: Testsuite will probably fail])
116    else
117      dnl Default to sse2.
118      test "$enable_sse" != yes || enable_sse=sse2
119      if test yes = "$GXX"; then
120        AC_MSG_RESULT([yes (configure with --disable-sse to disable)])
121        dnl We can unconditionally use -mtune=generic as it was added in GCC
122        dnl 4.2, and supported at least as far back as clang 3.0.
123        AM_CXXFLAGS="$AM_CXXFLAGS -mfpmath=sse -m$enable_sse -mtune=generic"
124      else
125        AC_MSG_RESULT([don't know how to for compiler $CXX])
126      fi
127    fi
128    ;;
129  *)
130    AC_MSG_RESULT([non-x86 arch ($host_cpu)]) ;;
131esac
132
133dnl The wxWidgets libraries we need:
134wx_libs="core,gl"
135
136AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
137AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
138: ${WX_CONFIG="$WXCONFIG"}
139
140AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
141AM_CONDITIONAL(MACOS, [test yes = "$macos"])
142
143if test -n "$WX_CONFIG" ; then
144  dnl WX_CONFIG specified - sanity check the value
145  dnl don't check for --ldflags - older wx-config didn't do that
146  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
147    :
148  else
149    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
150  fi
151else
152  if test yes = "$macos" ; then
153    wxdef=__WXMAC__
154  elif test yes = "$mswindows" ; then
155    wxdef=__WXMSW__
156  else
157    wxdef=__WXGTK__
158  fi
159  dnl See if wx-config exists and is for the correct version.
160  dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
161  dnl preference.
162  dnl Arch Linux uses wx-config-gtk3.
163  AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config-gtk3 wx-config])
164  if test -n "$WX_CONFIG" ; then
165    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
166      :
167    else
168      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
169    fi
170  else
171    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
172  fi
173fi
174
175dnl Unless the user has explicitly specified a --unicode setting, prefer
176dnl --unicode=yes if we can get it.
177case $WX_CONFIG in
178  *--unicode=*) ;;
179  *)
180    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
181      WX_CONFIG="$WX_CONFIG --unicode=yes"
182    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
183      WX_CONFIG="$WX_CONFIG --unicode=no"
184    fi ;;
185esac
186
187WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
188dnl Needed for nvidia drivers on linux (for some setups anyway).
189AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
190
191save_LIBS=$LIBS
192dnl Check if we need a library for OpenGL functions.  Usually it's the "GL"
193dnl library, but it's called opengl32 on Microsoft Windows).
194AC_SEARCH_LIBS([glPushMatrix], [GL opengl32], [WX_LIBS="$WX_LIBS $ac_cv_search_glPushMatrix"], [], [$WX_LIBS])
195dnl Check if we need a library for GLU functions.  Usually it's the "GLU"
196dnl library, but it's called glu32 on Microsoft Windows).
197AC_SEARCH_LIBS([gluProject], [GLU glu32], [WX_LIBS="$WX_LIBS $ac_cv_search_gluProject"], [], [$WX_LIBS])
198LIBS=$save_LIBS
199
200AC_SUBST(WX_LIBS)
201dnl macOS has OpenGL/gl.h and OpenGL/glu.h.
202AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
203AC_CHECK_HEADERS([GL/glu.h OpenGL/glu.h], [], [], [ ])
204dnl Older Debian mingw-w64 packages lacked GL/glext.h; macOS has OpenGL/glext.h.
205dnl Requires an explicit include of gl.h first.
206AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [
207  #ifdef HAVE_GL_GL_H
208  # include <GL/gl.h>
209  #elif defined HAVE_OPENGL_GL_H
210  # include <OpenGL/gl.h>
211  #endif
212  ])
213
214WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
215AC_SUBST(WX_CFLAGS)
216WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
217AC_SUBST(WX_CXXFLAGS)
218
219AC_LANG([C])
220save_CFLAGS=$CFLAGS
221CFLAGS="$CFLAGS $WX_CFLAGS"
222AC_CHECK_SIZEOF([wxChar], [], [
223  #include <wx/defs.h>
224  #include <wx/chartype.h>
225])
226CFLAGS=$save_CFLAGS
227
228dnl Check for FFmpeg libraries.
229PKG_CHECK_MODULES([FFMPEG], [libavcodec libavformat libswscale libavutil], [
230  AC_DEFINE([WITH_FFMPEG], [1], [Use FFmpeg for movie export])
231  save_CXXFLAGS=$CXXFLAGS
232  save_LIBS=$LIBS
233  CFLAGS="$CFLAGS $FFMPEG_CFLAGS"
234  LIBS="$LIBS $FFMPEG_LIBS"
235  AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
236  AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
237  AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
238  AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
239  AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
240  CXXFLAGS=$save_CXXFLAGS
241  LIBS=$save_LIBS
242], [
243  dnl Build without movie export feature.
244])
245AC_SUBST([FFMPEG_LIBS])
246AC_SUBST([FFMPEG_CFLAGS])
247
248dnl Check for PROJ.
249PKG_CHECK_MODULES([PROJ], [proj >= 6.2.0], [
250], [
251  dnl pkg-config support in proj seems quite new, so probe directly if not
252  dnl found.  We need proj_create_crs_to_crs_from_pj() which was added in
253  dnl 6.2.0.
254  AC_CHECK_LIB([proj], [proj_create_crs_to_crs_from_pj], [
255      PROJ_LIBS=-lproj
256      PROJ_CFLAGS=
257    ], [
258      AC_MSG_ERROR([PROJ required for coordinate transformations])
259    ])
260])
261AC_SUBST([PROJ_LIBS])
262AC_SUBST([PROJ_CFLAGS])
263
264dnl Check for GDAL.
265PKG_CHECK_MODULES([GDAL], [gdal >= 2.3], [
266  AC_DEFINE([HAVE_GDAL], [1], [Define to 1 if you have the 'GDAL' library.])
267], [
268  if test "$mswindows" = no ; then
269    AC_MSG_ERROR([GDAL required for geodata handling])
270  else
271    AC_MSG_WARN([GDAL required for geodata handling])
272  fi
273])
274AC_SUBST([GDAL_LIBS])
275AC_SUBST([GDAL_CFLAGS])
276
277dnl Checks for header files.
278
279AC_CHECK_HEADERS(string.h)
280
281AC_CHECK_FUNCS([popen hypot mmap strdup])
282
283dnl We don't access a FILE* from multiple threads and using the unlocked
284dnl versions has significantly less overhead, especially when reading/writing
285dnl byte-by-byte.  These are specified by POSIX:
286AC_CHECK_FUNCS([getc_unlocked putc_unlocked putchar_unlocked])
287dnl These are GNU extensions in glibc:
288AC_CHECK_FUNCS([feof_unlocked ferror_unlocked fread_unlocked fwrite_unlocked])
289
290AC_CHECK_FUNCS([setenv unsetenv])
291
292AC_CHECK_FUNCS([fmemopen])
293
294dnl Microsoft-specific functions which support positional argument specifiers.
295AC_CHECK_FUNCS([_vfprintf_p _vsprintf_p])
296
297AC_PATH_PROG([SPHINX_BUILD], [sphinx-build], [$MISSING sphinx-build])
298AC_ARG_VAR([SPHINX_BUILD], [sphinx-build from python3-sphinx])
299
300AC_PATH_PROG([MSGFMT], [msgfmt], [$MISSING msgfmt])
301AC_ARG_VAR([MSGFMT], [msgfmt from gettext])
302
303AC_ARG_ENABLE([werror],
304  [AS_HELP_STRING([--enable-werror], [enable treating compiler warnings as errors [default=no]])],
305  [case ${enableval} in
306    yes|no) ;;
307  *) AC_MSG_ERROR([bad value ${enableval} for --enable-werror]) ;;
308  esac],
309  [enable_werror=no])
310
311dnl Put -Werror or equivalent in its own make variable so that it can easily
312dnl be overridden by `make WERROR=` if needed during development (e.g. if
313dnl you want to get a full list of compile warnings to fix rather than
314dnl stopping at the first file with warnings).
315WERROR=
316AC_SUBST([WERROR])
317
318dnl extra warning flags for building with GCC
319if test yes = "$GCC"; then
320  WERROR=-Werror
321  if test yes = "$cross_compiling"; then
322dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
323dnl      -Wwrite-strings -Wcast-align"
324dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
325dnl to disable it for mingw builds.
326    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
327      -Wwrite-strings -Wcast-align"
328    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
329      -Wwrite-strings -Wcast-align -Wno-sign-compare"
330  else
331    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
332      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
333      -Wcast-align"
334    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
335      -Wwrite-strings -Wcast-align"
336  fi
337  dnl too many complaints from headers, etc: -Wconversion
338fi
339AC_SUBST(AM_CFLAGS)
340AC_SUBST(AM_CXXFLAGS)
341
342if test x$enable_werror != xyes; then
343  WERROR=
344fi
345
346dnl See if large file support is available.  Survex is unlikely to need to
347dnl process files > 2GB in size, but LFS is also needed for stat() to work
348dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
349AC_SYS_LARGEFILE
350
351AC_ARG_ENABLE(profiling,
352[  --enable-profiling Build binaries to generate profiling information],
353[case $enableval in
354  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
355       AM_CFLAGS="$AM_CFLAGS -pg"
356       AC_MSG_RESULT(building binaries to generate profiling information);;
357  no) ;;
358  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
359esac])
360
361EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
362AC_SUBST(EXTRA_TEXT)
363
364AC_SUBST_FILE(DESC)
365DESC=desc.txt
366AC_SUBST_FILE(AVENDESC)
367AVENDESC=desc-aven.txt
368
369dnl Don't define DATADIR if building for MS Windows - it won't be used, and
370dnl can conflict with the DATADIR typedef in objidl.h
371if test no = "$mswindows"; then
372  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
373fi
374
375AH_BOTTOM(
376[/* Use _unlocked() variants of stdio functions where available, since they are
377 * faster, and we don't multithread file accesses.
378 */
379
380#ifdef HAVE_FEOF_UNLOCKED
381# define FEOF(F) feof_unlocked(F)
382#else
383# define FEOF(F) feof(F)
384#endif
385
386#ifdef HAVE_FERROR_UNLOCKED
387# define FERROR(F) ferror_unlocked(F)
388#else
389# define FERROR(F) ferror(F)
390#endif
391
392#ifdef HAVE_FREAD_UNLOCKED
393# define FREAD(P, S, N, F) fread_unlocked(P, S, N, F)
394#else
395# define FREAD(P, S, N, F) fread(P, S, N, F)
396#endif
397
398/* If we call this FWRITE() then macos errors out on uses with:
399 * error: called object type 'int' is not a function or function pointer
400 * Unclear what's going on - a conditional `#undef FWRITE` before defining
401 * doesn't help.
402 */
403#ifdef HAVE_FWRITE_UNLOCKED
404# define FWRITE_(P, S, N, F) fwrite_unlocked(P, S, N, F)
405#else
406# define FWRITE_(P, S, N, F) fwrite(P, S, N, F)
407#endif
408
409#ifdef HAVE_GETC_UNLOCKED
410# define GETC(F) getc_unlocked(F)
411#else
412# define GETC(F) getc(F)
413#endif
414
415#ifdef HAVE_PUTC_UNLOCKED
416# define PUTC(C, F) putc_unlocked(C, F)
417#else
418# define PUTC(C, F) putc(C, F)
419#endif
420
421#ifdef HAVE_PUTC_UNLOCKED
422# define PUTCHAR(C) putchar_unlocked(C)
423#else
424# define PUTCHAR(C) putchar(C)
425#endif
426
427#ifndef __cplusplus
428/* C23 added bool, false and true as keywords - let's emulate that and
429 * avoid every C file which uses these needing to include <stdbool.h>.
430 */
431# include <stdbool.h>
432#endif
433])
434
435AC_CONFIG_FILES([
436 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
437 lib/images/Makefile
438 tests/Makefile vim/Makefile survex.iss doc/index.htm
439 survex.spec lib/Info.plist
440 ])
441AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.