source: git/survex.iss.in @ 1908f42

RELEASE/1.2debug-cidebug-ci-sanitisersstereowalls-data
Last change on this file since 1908f42 was d417499, checked in by Olly Betts <olly@…>, 8 years ago

Prefer https for survex.com and other sites which support it
  • Property mode set to 100644
File size: 8.5 KB
Line 
1; @configure_input@
2[Setup]
3AppName=@PRETTYPACKAGE@
4; AppVerName not required by InnoSetup >= 5.3.10
5AppVerName=@PRETTYPACKAGE@ @VERSION@
6DefaultDirName={pf32}\@PRETTYPACKAGE@
7DefaultGroupName=@PRETTYPACKAGE@
8OutputBaseFilename=@PACKAGE@-win32-@VERSION@
9; FIXME translate this!
10;AppComments=Survex Cave Surveying Software
11AppPublisher=The Survex Project
12AppPublisherURL=https://survex.com/
13AppVersion=@VERSION@
14VersionInfoTextVersion=@VERSION@
15VersionInfoVersion=@VERSION@
16ChangesAssociations=yes
17LicenseFile=COPYING.txt
18Uninstallable=yes
19AppCopyright=@COPYRIGHT_MSG@
20;WizardImageFile=survey.bmp
21;WizardSmallImageFile=??? (up to 55x58)
22LZMANumFastBytes=273
23SolidCompression=yes
24; Only show the "choose language" dialog if there isn't an exact match for
25; the UI language the user has set.
26ShowLanguageDialog=auto
27;SetupIconFile=FIXME ; file in installation source directory
28;UninstallDisplayIcon=FIXME
29;AppReadmeFile=FIXME
30;AppSupportURL=FIXME
31;AppUpdatesURL=FIXME
32AppContact=olly@survex.com
33; Install file timestamps correctly!
34TimeStampsInUTC=yes
35; SignedUninstaller ???
36; If upgrading, default to the language selected last time.
37UsePreviousLanguage=yes
38; If upgrading, install to the same location and use the same start menu folder.
39DisableDirPage=auto
40DisableProgramGroupPage=auto
41; Disable the "welcome" page of the wizard.
42DisableWelcomePage=yes
43
44[Languages]
45; Official translations:
46Name: "ca"; MessagesFile: "compiler:Languages/Catalan.isl"
47Name: "cs"; MessagesFile: "compiler:Languages/Czech.isl"
48Name: "de"; MessagesFile: "compiler:Languages/German.isl"
49Name: "en"; MessagesFile: "compiler:Default.isl"
50Name: "el"; MessagesFile: "compiler:Languages/Greek.isl"
51Name: "es"; MessagesFile: "compiler:Languages/Spanish.isl"
52Name: "fr"; MessagesFile: "compiler:Languages/French.isl"
53Name: "hu"; MessagesFile: "compiler:Languages/Hungarian.isl"
54Name: "it"; MessagesFile: "compiler:Languages/Italian.isl"
55Name: "pl"; MessagesFile: "compiler:Languages/Polish.isl"
56Name: "pt"; MessagesFile: "compiler:Languages/Portuguese.isl"
57Name: "pt_br"; MessagesFile: "compiler:Languages/BrazilianPortuguese.isl"
58Name: "ru"; MessagesFile: "compiler:Languages/Russian.isl"
59; Unofficial:
60Name: "bg"; MessagesFile: "Bulgarian.isl"
61Name: "en_gb"; MessagesFile: "EnglishBritish.isl"
62Name: "id"; MessagesFile: "Indonesian.isl"
63Name: "ro"; MessagesFile: "Romanian.isl"
64Name: "sk"; MessagesFile: "Slovak.isl"
65Name: "zh_CN"; MessagesFile: "ChineseSimplified.isl"
66Name: "zh_TW"; MessagesFile: "ChineseTraditional.isl"
67
68[Dirs]
69Name: "{app}\manual"
70Name: "{app}\images"
71
72[Files]
73Source: "*.exe"; DestDir: "{app}"
74; mingwm10.dll only needed if we use threads
75;Source: "*.dll"; DestDir: "{app}"
76Source: "*.svx"; DestDir: "{app}"
77Source: "*.ico"; DestDir: "{app}"
78Source: "*.pixelfont"; DestDir: "{app}"
79Source: "*.png"; DestDir: "{app}\images"
80Source: "*.msg"; DestDir: "{app}"
81Source: "*.htm"; DestDir: "{app}"
82Source: "manual\*.*"; DestDir: "{app}\manual"
83Source: "proj\*.*"; DestDir: "{app}\proj"
84; Generate iss file for including the wxstd.mo files
85#include "i18nfiles.iss"
86
87; FIXME This should be translated (think there's a standard custommessage)
88;[Run]
89;Filename: "{app}\aven.exe"; Description: "Launch aven"; Flags: postinstall nowait skipifsilent unchecked
90
91[Icons]
92; Name: "{group}\SvxEdit"; Filename: "{app}\editwrap.exe"; Comment: "Enter survey data"
93Name: "{group}\Aven"; Filename: "{app}\aven.exe"; Comment: "View processed surveys"
94Name: "{group}\Documentation"; Filename: "{app}\index.htm"; Comment: "View the documentation for Survex"
95Name: "{group}\{cm:UninstallProgram,@PRETTYPACKAGE@}"; Filename: "{uninstallexe}"
96
97[Registry]
98; Support for loading Compass Plot files
99Root: HKCR; Subkey: ".plt"; ValueType: string; ValueData: "CompassPlotFile"
100Root: HKCR; Subkey: ".plf"; ValueType: string; ValueData: "CompassPlotFile"
101Root: HKCR; Subkey: "CompassPlotFile"; ValueType: string; ValueData: "Compass Plot File"
102Root: HKCR; Subkey: "CompassPlotFile\DefaultIcon"; ValueType: string; ValueData:"{app}\plt.ico"
103Root: HKCR; Subkey: "CompassPlotFile\shell\Open with Aven\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletekey
104; Support for loading CMAP XYZ files
105Root: HKCR; Subkey: ".xyz"; ValueType: string; ValueData: "CMAP.XYZ"
106Root: HKCR; Subkey: "CMAP.XYZ"; ValueType: string; ValueData: "CMAP Processed Data"
107;Root: HKCR; Subkey: "CMAP.XYZ\DefaultIcon"; ValueType: string; ValueData:"{app}\plt.ico"
108Root: HKCR; Subkey: "CMAP.XYZ\shell\Open with Aven\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletekey
109;
110Root: HKCR; Subkey: ".svx"; ValueType: string; ValueData: "survex.source"; Flags: uninsdeletevalue
111Root: HKCR; Subkey: ".3d"; ValueType: string; ValueData: "survex.bin"; Flags: uninsdeletevalue
112Root: HKCR; Subkey: ".err"; ValueType: string; ValueData: "survex.error"; Flags: uninsdeletevalue
113Root: HKCR; Subkey: ".pos"; ValueType: string; ValueData: "survex.pos"; Flags: uninsdeletevalue
114Root: HKCR; Subkey: ".log"; ValueType: string; ValueData: "survex.log"; Flags: uninsdeletevalue
115Root: HKCR; Subkey: "survex.source"; ValueType: string; ValueData: "Survex Raw Survey Data"; Flags: uninsdeletevalue
116Root: HKCR; Subkey: "survex.source\DefaultIcon"; ValueType: string; ValueData: "{app}\svx.ico"; Flags: uninsdeletevalue
117Root: HKCR; Subkey: "survex.source\shell\Open"; ValueType: none; Flags: deletekey
118Root: HKCR; Subkey: "survex.source\shell\Process"; ValueType: none; Flags: deletekey
119Root: HKCR; Subkey: "survex.source\shell\Open in Notepad\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
120;Root: HKCR; Subkey: "survex.source\shell\Open in SvxEdit\command"; ValueType: string; ValueData: """{app}\editwrap.exe"" ""%1"""; Flags: uninsdeletevalue
121Root: HKCR; Subkey: "survex.source\shell\Process\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletevalue
122Root: HKCR; Subkey: "survex.bin"; ValueType: string; ValueData: "Survex Processed Data"; Flags: uninsdeletevalue
123Root: HKCR; Subkey: "survex.bin\DefaultIcon"; ValueType: string; ValueData:"{app}\3d.ico"; Flags: uninsdeletevalue
124Root: HKCR; Subkey: "survex.bin\shell\Open\command"; ValueType: string; ValueData: """{app}\aven.exe"" ""%1"""; Flags: uninsdeletevalue
125Root: HKCR; Subkey: "survex.bin\shell\Print\command"; ValueType: string; ValueData: """{app}\aven.exe"" --print ""%1"""; Flags: uninsdeletevalue
126Root: HKCR; Subkey: "survex.bin\shell\Extend\command"; ValueType: string; ValueData: """{app}\extend.exe"" ""%1"""; Flags: uninsdeletevalue
127Root: HKCR; Subkey: "survex.bin\shell\Convert to DXF\command"; ValueType: string; ValueData: """{app}\cad3d.exe"" --dxf ""%1"""; Flags: uninsdeletevalue
128Root: HKCR; Subkey: "survex.bin\shell\Convert for hand plotting\command"; ValueType: string; ValueData: """{app}\3dtopos.exe"" ""%1"""; Flags: uninsdeletevalue
129Root: HKCR; Subkey: "survex.error"; ValueType: string; ValueData: "Survex Loop Closure Errors"; Flags: uninsdeletevalue
130Root: HKCR; Subkey: "survex.error\DefaultIcon"; ValueType: string; ValueData: "{app}\err.ico"; Flags: uninsdeletevalue
131Root: HKCR; Subkey: "survex.error\shell\Open\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
132Root: HKCR; Subkey: "survex.error\shell\Sort by Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r ""%1"""; Flags: uninsdeletevalue
133Root: HKCR; Subkey: "survex.error\shell\Sort by Horizontal Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -h ""%1"""; Flags: uninsdeletevalue
134Root: HKCR; Subkey: "survex.error\shell\Sort by Vertical Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -v ""%1"""; Flags: uninsdeletevalue
135Root: HKCR; Subkey: "survex.error\shell\Sort by Percentage Error\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -p ""%1"""; Flags: uninsdeletevalue
136Root: HKCR; Subkey: "survex.error\shell\Sort by Error per Leg\command"; ValueType: string; ValueData: """{app}\sorterr.exe"" -r -l ""%1"""; Flags: uninsdeletevalue
137Root: HKCR; Subkey: "survex.pos"; ValueType: string; ValueData: "Survex Station Positions"; Flags: uninsdeletevalue
138Root: HKCR; Subkey: "survex.pos\DefaultIcon"; ValueType: string; ValueData: "{app}\pos.ico"; Flags: uninsdeletevalue
139Root: HKCR; Subkey: "survex.pos\shell\Open\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
140Root: HKCR; Subkey: "survex.log"; ValueType: string; ValueData: "Output Log"; Flags: uninsdeletevalue
141Root: HKCR; Subkey: "survex.log\shell\Open\command"; ValueType: string; ValueData: """notepad.exe"" ""%1"""; Flags: uninsdeletevalue
Note: See TracBrowser for help on using the repository browser.