source: git/configure.in @ 9e516d0d

RELEASE/1.2debug-cidebug-ci-sanitisersstereowalls-data
Last change on this file since 9e516d0d was 9e516d0d, checked in by Olly Betts <olly@…>, 13 years ago

configure.in,src/moviemaker.cc,src/moviemaker.h: Use libswscale to
convert images to add to the video. Movie export now working
again!

git-svn-id: file:///home/survex-svn/survex/trunk@3619 4b37db11-9a0c-4f06-9ece-9ab7cdaee568

  • Property mode set to 100644
File size: 11.3 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl CFLAGS=-DDEFAULTLANG=fr to build with French as the default language.
4
5dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
6dnl long enough, that we might as well just require that.
7AC_PREREQ(2.59)
8AC_INIT(src/aven.cc)
9
10AM_INIT_AUTOMAKE(survex, 1.1.16)
11RELEASE=1
12
13AC_SUBST(RELEASE)
14AC_CONFIG_HEADERS([config.h])
15
16COPYRIGHT_MSG="Copyright (C) 1990-2011 Olly Betts"
17AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
18
19AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
20AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
21                   [Copyright Message for Aven])
22
23AC_SUBST(COPYRIGHT_MSG)
24AC_SUBST(AVEN_COPYRIGHT_MSG)
25
26COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
27AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
28
29AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message in UTF-8])
31AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
32                   [Copyright Message for Aven in UTF-8])
33
34dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
35PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
36AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
37                   [Name of package (capitalised)])
38AC_SUBST(PRETTYPACKAGE)
39
40dnl set COMMAVERSION to VERSION with the dots replaced by commas -
41dnl e.g. "0,99" or "1,0,22"
42COMMAVERSION=`echo "$VERSION"|tr '.' ','`
43AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
44                   [Version number of package (comma-separated)])
45AC_SUBST(COMMAVERSION)
46
47PKGDOCDIR='${prefix}/doc/${PACKAGE}'
48AC_ARG_ENABLE(docdir,
49[  --enable-docdir=DIR Set directory for installing documentation to DIR],
50[case $enableval in
51 yes|no)
52  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
53esac
54PKGDOCDIR="$enableval"
55]
56)
57PKGDOCDIR_EXPANDED=`(
58 test NONE = "$prefix" && prefix="$ac_default_prefix"
59 test NONE = "$exec_prefix" && exec_prefix="$prefix"
60 eval echo "$PKGDOCDIR"
61)`
62AC_SUBST(PKGDOCDIR)
63AC_SUBST(PKGDOCDIR_EXPANDED)
64
65DEFAULTLANG=en
66AC_ARG_ENABLE(defaultlang,
67[  --enable-defaultlang=LANG Set the default language for messages to LANG],
68[case $enableval in
69 yes|no) # until we support Norwegian...
70  AC_MSG_ERROR([configure: Syntax: configure --enable-defaultlang=LANGUAGE]) ;;
71esac
72DEFAULTLANG="$enableval"
73AC_DEFINE_UNQUOTED(DEFAULTLANG, [$enableval], [Default language for messages])
74]
75)
76AC_SUBST(DEFAULTLANG)
77
78AC_ARG_ENABLE(testprogs,
79[  --enable-testprogs Enable building of various test harness programs],
80[case $enableval in
81 yes) TESTPROGS=dump3d ;;
82 no) TESTPROGS= ;;
83 *) AC_MSG_ERROR(bad value $enableval for --enable-testprogs) ;;
84esac
85]
86AC_SUBST(TESTPROGS)
87)
88
89AC_CANONICAL_HOST
90
91dnl Checks for programs.
92AC_PROG_CC
93AC_PROG_CPP
94
95AC_PROG_CXX
96AC_PROG_CXXCPP
97
98AM_PROG_CC_C_O
99
100AC_LANG_C
101
102AC_C_INLINE
103
104AC_EXEEXT
105AC_OBJEXT
106
107mswindows=no
108macosx=no
109case $host_os in
110darwin*) macosx=yes ;;
111*mingw*|*cygwin*|windows*) mswindows=yes ;;
112esac
113
114AC_C_BIGENDIAN
115
116AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
117AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
118
119AC_CHECK_LIB(m, sqrt)
120
121AC_PATH_XTRA
122
123WINPROGS=
124if test yes = "$mswindows"; then
125  WINPROGS='editwrap$(EXEEXT)'
126  AC_MSG_RESULT(building editwrap)
127fi
128AC_SUBST(WINPROGS)
129
130dnl The wxWidgets libraries we need:
131wx_libs="core,gl,html"
132
133AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
134AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
135: ${WX_CONFIG="$WXCONFIG"}
136
137AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
138AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
139
140if test -n "$WX_CONFIG" ; then
141  dnl WX_CONFIG specified - sanity check the value
142  dnl don't check for --ldflags - older wx-config didn't do that
143  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
144    :
145  else
146    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
147  fi
148else
149  if test yes = "$macosx" ; then
150    wxdef=__WXMAC__
151  elif test yes = "$mswindows" ; then
152    wxdef=__WXMSW__
153  else
154    wxdef=__WXGTK__
155  fi
156  dnl See if wx-config exists and is for the correct version.
157  AC_PATH_PROGS(WX_CONFIG, [wx-config])
158  if test -n "$WX_CONFIG" ; then
159    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
160      :
161    else
162      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
163    fi
164  else
165    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
166  fi
167fi
168
169dnl Unless the user has explicitly specified a --unicode setting, prefer
170dnl --unicode=yes if we can get it.
171case $WX_CONFIG in
172  *--unicode=*) ;;
173  *)
174    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
175      WX_CONFIG="$WX_CONFIG --unicode=yes"
176    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
177      WX_CONFIG="$WX_CONFIG --unicode=no"
178    fi ;;
179esac
180
181WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
182dnl Needed for nvidia drivers on linux (for some setups anyway).
183AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
184dnl We use functions from libGLU so always link -lGLU explicitly if it's
185dnl present.
186AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
187dnl We use functions from libGL so always link -lGL explicitly if it's
188dnl present.
189AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
190AC_SUBST(WX_LIBS)
191
192dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
193dnl stderr, with nothing to stdout, so just ignore stderr.
194WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
195AC_SUBST(WX_LDFLAGS)
196WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
197AC_SUBST(WX_CFLAGS)
198WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
199AC_SUBST(WX_CXXFLAGS)
200
201dnl Check for ffmpeg
202MOVIE_LIBS=
203AC_CHECK_LIB(avcodec, avcodec_init,
204  [AC_CHECK_LIB(avformat, av_register_all,
205    [AC_CHECK_LIB(swscale, sws_scale,
206      [AC_CHECK_HEADERS([libavformat/avformat.h],
207        [MOVIE_LIBS="-lswscale -lavformat -lavcodec"])],
208      [], [-lavformat -lavcodec $WX_LIBS])],
209    [], [-lavcodec $WX_LIBS])
210])
211AC_SUBST(MOVIE_LIBS)
212
213AC_LANG_C
214
215dnl Checks for header files.
216AC_HEADER_STDC
217dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
218AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
219
220dnl Checks for typedefs, structures, and compiler characteristics.
221AC_C_CONST
222AC_TYPE_SIZE_T
223AC_STRUCT_TM
224AC_TYPE_SIGNAL
225
226dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
227dnl if it isn't, assume it is 1000000, as it is on SunOS 4
228AC_TRY_COMPILE([#include <time.h>],[
229#ifndef CLOCKS_PER_SEC
230choke me
231#endif
232], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
233
234dnl Check for 16-bit and 32-bit integer types.
235AC_TYPE_INT16_T
236AC_TYPE_INT32_T
237
238dnl Checks for library functions.
239AC_FUNC_STRFTIME
240if test yes != "$ac_cv_func_strftime"; then
241  AC_LIBOBJ(strftime)
242fi
243AC_FUNC_VPRINTF
244dnl check for strcasecmp here as well as below - this one is to get
245dnl HAVE_STRCASECMP defined if appropriate (for img.c)
246AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
247
248dnl difftime seems to be an ANSI invention
249AC_CHECK_FUNCS(difftime)
250
251dnl Much faster than using getc()/putc(), at least on Linux.
252AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
253
254dnl try to find a case-insensitive compare
255
256strcasecmp=no
257dnl The order of these tests is important.
258AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
259if test no = "$strcasecmp"; then
260  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
261fi
262if test no = "$strcasecmp"; then
263  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
264fi
265
266AC_MSG_CHECKING([how to compare strings ignoring case])
267case $strcasecmp in
268no)
269  AC_LIBOBJ(strcasecmp)
270  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
271strcasecmp)
272  AC_MSG_RESULT([strcasecmp]) ;;
273*)
274  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
275    [strcasecmp define for systems which call it something else])
276  AC_MSG_RESULT([$strcasecmp]) ;;
277esac
278
279AC_MSG_CHECKING(for sgmltools v2 or v3)
280if test : != "$SGMLTOOLS" ; then
281  : ${SGMLTOOLS=sgmltools}
282  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
283  *" version 3"*)
284    AC_MSG_RESULT([$SGMLTOOLS]) ;;
285  *" version 2"*)
286    AC_MSG_RESULT([$SGMLTOOLS]) ;;
287  *)
288    SGMLTOOLS="$MISSING sgmltools"
289    AC_MSG_RESULT(not found) ;;
290  esac
291else
292  AC_MSG_RESULT([$SGMLTOOLS])
293fi
294AC_SUBST(SGMLTOOLS)
295AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
296
297AC_MSG_CHECKING(for docbook-to-man)
298if test : != "$DOCBOOK_TO_MAN" ; then
299  : ${DOCBOOK_TO_MAN=docbook-to-man}
300  $DOCBOOK_TO_MAN 2> /dev/null
301  if test $? = 1 ; then
302    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
303  else
304    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
305    AC_MSG_RESULT([not found])
306  fi
307else
308  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
309fi
310AC_SUBST(DOCBOOK_TO_MAN)
311AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
312
313dnl extra warning flags for building with GCC
314if test yes = "$GCC"; then
315  if test yes = "$cross_compiling"; then
316dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
317dnl      -Wwrite-strings -Wcast-align"
318dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
319dnl to disable it for mingw builds.
320    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
321      -Wwrite-strings -Wcast-align"
322    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
323      -Wwrite-strings -Wcast-align -Wno-sign-compare"
324  else
325    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
326      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
327      -Wcast-align"
328    dnl -W causes problems with wxWidgets
329    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wshadow -Wpointer-arith\
330      -Wwrite-strings -Wcast-align"
331  fi
332  dnl too many complaints from headers, etc: -Wconversion
333fi
334AC_SUBST(AM_CFLAGS)
335AC_SUBST(AM_CXXFLAGS)
336
337AC_ARG_ENABLE(profiling,
338[  --enable-profiling Build binaries to generate profiling information],
339[case $enableval in
340  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
341       AM_CFLAGS="$AM_CFLAGS -pg"
342       AC_MSG_RESULT(building binaries to generate profiling information);;
343  no) ;;
344  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
345esac])
346
347HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm"
348AC_SUBST(HTMLFILES)
349
350EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
351AC_SUBST(EXTRA_TEXT)
352
353AC_SUBST_FILE(DESC)
354DESC=desc.txt
355AC_SUBST_FILE(AVENDESC)
356AVENDESC=desc-aven.txt
357AC_SUBST_FILE(SVXEDITDESC)
358SVXEDITDESC=desc-svxedit.txt
359
360dnl Don't define DATADIR if building for MS Windows - it won't be used, and
361dnl can conflict with the DATADIR typedef in objidl.h
362if test no = "$mswindows"; then
363  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
364fi
365
366AH_BOTTOM(
367[/* Use getc_unlocked() and putc_unlocked() where available, since they are
368 * faster, and we don't multithread file accesses.
369 */
370
371#ifdef HAVE_GETC_UNLOCKED
372# define GETC(F) getc_unlocked(F)
373#else
374# define GETC(F) getc(F)
375#endif
376#ifdef HAVE_PUTC_UNLOCKED
377# define PUTC(C, F) putc_unlocked(C, F)
378#else
379# define PUTC(C, F) putc(C, F)
380#endif
381])
382
383AC_CONFIG_FILES([
384 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
385 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
386 doc/version.ent survex.spec src/svxedit lib/survex.keys lib/Info.plist
387 ])
388AC_OUTPUT
389dnl FIXME update msvc makefile for 1.1 branch
390dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.