source: git/configure.in @ 47105bc

RELEASE/1.1RELEASE/1.2debug-cidebug-ci-sanitisersstereowalls-data
Last change on this file since 47105bc was 47105bc, checked in by Olly Betts <olly@…>, 14 years ago

Remove .deb building machinery from upstream Makefile.

git-svn-id: file:///home/survex-svn/survex/branches/survex-1_1@3378 4b37db11-9a0c-4f06-9ece-9ab7cdaee568

  • Property mode set to 100644
File size: 11.5 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl CFLAGS=-DDEFAULTLANG=fr to build with French as the default language.
4
5dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
6dnl long enough, that we might as well just require that.
7AC_PREREQ(2.59)
8AC_INIT(src/aven.cc)
9
10AM_INIT_AUTOMAKE(survex, 1.1.13)
11RELEASE=1
12
13AC_SUBST(RELEASE)
14AM_CONFIG_HEADER(config.h)
15
16COPYRIGHT_MSG="Copyright (C) 1990-2010 Olly Betts"
17AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
18
19AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
20AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
21                   [Copyright Message for Aven])
22
23AC_SUBST(COPYRIGHT_MSG)
24AC_SUBST(AVEN_COPYRIGHT_MSG)
25
26COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
27AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
28
29AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message in UTF-8])
31AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
32                   [Copyright Message for Aven in UTF-8])
33
34dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
35PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
36AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
37                   [Name of package (capitalised)])
38AC_SUBST(PRETTYPACKAGE)
39
40dnl set COMMAVERSION to VERSION with the dots replaced by commas -
41dnl e.g. "0,99" or "1,0,22"
42COMMAVERSION=`echo "$VERSION"|tr '.' ','`
43AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
44                   [Version number of package (comma-separated)])
45AC_SUBST(COMMAVERSION)
46
47PKGDOCDIR='${prefix}/doc/${PACKAGE}'
48AC_ARG_ENABLE(docdir,
49[  --enable-docdir=DIR Set directory for installing documentation to DIR],
50[case $enableval in
51 yes|no)
52  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
53esac
54PKGDOCDIR="$enableval"
55]
56)
57PKGDOCDIR_EXPANDED=`(
58 test NONE = "$prefix" && prefix="$ac_default_prefix"
59 test NONE = "$exec_prefix" && exec_prefix="$prefix"
60 eval echo "$PKGDOCDIR"
61)`
62AC_SUBST(PKGDOCDIR)
63AC_SUBST(PKGDOCDIR_EXPANDED)
64
65DEFAULTLANG=en
66AC_ARG_ENABLE(defaultlang,
67[  --enable-defaultlang=LANG Set the default language for messages to LANG],
68[case $enableval in
69 yes|no) # until we support Norwegian...
70  AC_MSG_ERROR([configure: Syntax: configure --enable-defaultlang=LANGUAGE]) ;;
71esac
72DEFAULTLANG="$enableval"
73AC_DEFINE_UNQUOTED(DEFAULTLANG, [$enableval], [Default language for messages])
74]
75)
76AC_SUBST(DEFAULTLANG)
77
78AC_ARG_ENABLE(testprogs,
79[  --enable-testprogs Enable building of various test harness programs],
80[case $enableval in
81 yes) TESTPROGS=dump3d ;;
82 no) TESTPROGS= ;;
83 *) AC_MSG_ERROR(bad value $enableval for --enable-testprogs) ;;
84esac
85]
86AC_SUBST(TESTPROGS)
87)
88
89AC_CANONICAL_HOST
90
91dnl Checks for programs.
92AC_PROG_CC
93AC_PROG_CPP
94
95AC_PROG_CXX
96AC_PROG_CXXCPP
97
98AM_PROG_CC_C_O
99
100AC_LANG_C
101
102AC_PROG_MAKE_SET
103
104AC_EXEEXT
105AC_OBJEXT
106
107case $host_os in
108*mingw*|*cygwin*|windows*) mswindows=yes ;;
109*) mswindows=no ;;
110esac
111
112case $host in
113powerpc-*-darwin*) macosx=yes ;; # wxWidgets uses this to detect MacOS X
114*) macosx=no ;;
115esac
116
117AC_C_BIGENDIAN
118
119AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
120AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
121
122AC_CHECK_LIB(m, sqrt)
123
124AC_PATH_XTRA
125
126WINPROGS=
127if test yes = "$mswindows"; then
128  WINPROGS='editwrap$(EXEEXT)'
129  AC_MSG_RESULT(building editwrap)
130fi
131AC_SUBST(WINPROGS)
132
133AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
134AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
135: ${WX_CONFIG="$WXCONFIG"}
136
137AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
138AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
139
140if test -n "$WX_CONFIG" ; then
141  dnl WX_CONFIG specified - sanity check the value
142  dnl don't check for --ldflags - older wx-config didn't do that
143  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags;exit $?) then
144    :
145  else
146    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags' doesn't work, bailing out])
147  fi
148else
149  if test yes = "$macosx" ; then
150    dnl FIXME: Not sure if this is useful for newer wx...
151    AC_PATH_PROGS(WX_CONFIG, [wxmac-2.8-config wxmac-2.6-config wxmac-2.7-config wxmac-config])
152    wxdef=__WXMAC__
153  elif test yes = "$mswindows" ; then
154    dnl FIXME: Not sure if this is useful for newer wx...
155    AC_PATH_PROGS(WX_CONFIG, [wxmsw-2.8-config wxmac-2.6-config wxmac-2.7-config wxmac-config])
156    wxdef=__WXMSW__
157  else
158    wxdef=__WXGTK__
159  fi
160  if test -z "$WX_CONFIG" ; then
161    dnl See if wx-config exists and is for the correct version.
162    AC_PATH_PROGS(WX_CONFIG, [wx-config])
163    if test -n "$WX_CONFIG" ; then
164      if (exec >&5 2>&5;$WX_CONFIG --cflags|grep -e -D"$wxdef";exit $?) then
165        :
166      else
167        WX_CONFIG=
168      fi
169    fi
170  fi
171  if test -z "$WX_CONFIG" ; then
172    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
173  fi
174fi
175
176dnl Unless the user has explicitly specified a --unicode setting, prefer
177dnl --unicode=yes if we can get it.
178case $WX_CONFIG in
179  *--unicode=*) ;;
180  *)
181    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version;exit $?) ; then
182      WX_CONFIG="$WX_CONFIG --unicode=yes"
183    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version;exit $?) ; then
184      WX_CONFIG="$WX_CONFIG --unicode=no"
185    fi ;;
186esac
187
188dnl Call wx-config twice to avoid getting a newline in WX_LIBS.
189WX_LIBS=`$WX_CONFIG --libs`" "`$WX_CONFIG --gl-libs`
190dnl Needed for nvidia drivers on linux (for some setups anyway).
191AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
192AC_SUBST(WX_LIBS)
193dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
194dnl stderr, with nothing to stdout, so just ignore stderr.
195WX_LDFLAGS=`$WX_CONFIG --ldflags 2> /dev/null`
196AC_SUBST(WX_LDFLAGS)
197WX_CFLAGS=`$WX_CONFIG --cflags`
198AC_SUBST(WX_CFLAGS)
199WX_CXXFLAGS=`$WX_CONFIG --cxxflags`
200AC_SUBST(WX_CXXFLAGS)
201
202dnl Check for ffmpeg
203MOVIE_LIBS=
204AC_CHECK_LIB(avcodec, avcodec_init,
205  [AC_CHECK_LIB(avformat, av_register_all,
206    [AC_CHECK_HEADERS([avformat.h],
207      [MOVIE_LIBS="-lavformat -lavcodec"])], [], [-lavcodec $WX_LIBS])])
208AC_SUBST(MOVIE_LIBS)
209
210AC_LANG_C
211
212dnl Checks for header files.
213AC_HEADER_STDC
214dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
215AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
216
217dnl Checks for typedefs, structures, and compiler characteristics.
218AC_C_CONST
219AC_TYPE_SIZE_T
220AC_STRUCT_TM
221AC_TYPE_SIGNAL
222
223dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
224dnl if it isn't, assume it is 1000000, as it is on SunOS 4
225AC_TRY_COMPILE([#include <time.h>],[
226#ifndef CLOCKS_PER_SEC
227choke me
228#endif
229], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
230
231dnl Look for a signed 32 bit integer type
232AC_MSG_CHECKING(for 32 bit integer type)
233AC_TRY_COMPILE(,[switch (0) { case (sizeof(int)==4): case 0: break; }],
234INT32_T=int,
235AC_TRY_COMPILE(,[switch (0) { case (sizeof(long)==4): case 0: break; }],
236INT32_T=long,
237AC_MSG_ERROR(not found)
238)
239)
240AC_MSG_RESULT($INT32_T)
241AC_DEFINE_UNQUOTED(INT32_T,$INT32_T,[signed 32 bit integer type])
242
243dnl Look for a signed 16 bit integer type
244AC_MSG_CHECKING(for 16 bit integer type)
245AC_TRY_COMPILE(,[switch (0) { case (sizeof(short)==2): case 0: break; }],
246INT16_T=short,
247AC_TRY_COMPILE(,[switch (0) { case (sizeof(int)==2): case 0: break; }],
248INT16_T=int,
249AC_MSG_ERROR(not found)
250)
251)
252AC_MSG_RESULT($INT16_T)
253AC_DEFINE_UNQUOTED(INT16_T,$INT16_T,[signed 16 bit integer type])
254
255dnl Checks for library functions.
256AC_FUNC_STRFTIME
257if test yes != "$ac_cv_func_strftime"; then
258  AC_LIBOBJ(strftime)
259fi
260AC_FUNC_VPRINTF
261dnl check for strcasecmp here as well as below - this one is to get
262dnl HAVE_STRCASECMP defined if appropriate (for img.c)
263AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
264
265dnl difftime seems to be an ANSI invention
266AC_CHECK_FUNCS(difftime)
267
268dnl try to find a case-insensitive compare
269
270strcasecmp=no
271dnl The order of these tests is important.
272AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
273if test no = "$strcasecmp"; then
274  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
275fi
276if test no = "$strcasecmp"; then
277  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
278fi
279
280AC_MSG_CHECKING([how to compare strings ignoring case])
281case $strcasecmp in
282no)
283  AC_LIBOBJ(strcasecmp)
284  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
285strcasecmp)
286  AC_MSG_RESULT([strcasecmp]) ;;
287*)
288  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
289    [strcasecmp define for systems which call it something else])
290  AC_MSG_RESULT([$strcasecmp]) ;;
291esac
292
293AC_MSG_CHECKING(for sgmltools v2 or v3)
294if test : != "$SGMLTOOLS" ; then
295  : ${SGMLTOOLS=sgmltools}
296  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
297  *" version 3"*)
298    AC_MSG_RESULT([$SGMLTOOLS]) ;;
299  *" version 2"*)
300    AC_MSG_RESULT([$SGMLTOOLS]) ;;
301  *)
302    SGMLTOOLS="$MISSING sgmltools"
303    AC_MSG_RESULT(not found) ;;
304  esac
305else
306  AC_MSG_RESULT([$SGMLTOOLS])
307fi
308AC_SUBST(SGMLTOOLS)
309AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
310
311AC_MSG_CHECKING(for docbook-to-man)
312if test : != "$DOCBOOK_TO_MAN" ; then
313  : ${DOCBOOK_TO_MAN=docbook-to-man}
314  $DOCBOOK_TO_MAN 2> /dev/null
315  if test $? = 1 ; then
316    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
317  else
318    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
319    AC_MSG_RESULT([not found])
320  fi
321else
322  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
323fi
324AC_SUBST(DOCBOOK_TO_MAN)
325AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
326
327dnl extra warning flags for building with GCC
328if test yes = "$GCC"; then
329  if test yes = "$cross_compiling"; then
330dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
331dnl      -Wwrite-strings -Wcast-align"
332dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
333dnl to disable it for mingw builds.
334    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
335      -Wwrite-strings -Wcast-align"
336    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
337      -Wwrite-strings -Wcast-align -Wno-sign-compare"
338  else
339    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
340      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
341      -Wcast-align"
342    dnl -W causes problems with wxWidgets
343    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wshadow -Wpointer-arith\
344      -Wwrite-strings -Wcast-align"
345  fi
346  dnl too many complaints from headers, etc: -Wconversion
347fi
348AC_SUBST(AM_CFLAGS)
349AC_SUBST(AM_CXXFLAGS)
350
351AC_ARG_ENABLE(profiling,
352[  --enable-profiling Build binaries to generate profiling information],
353[case $enableval in
354  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
355       AM_CFLAGS="$AM_CFLAGS -pg"
356       AC_MSG_RESULT(building binaries to generate profiling information);;
357  no) ;;
358  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
359esac])
360
361DOCS_OTHER="manual.rtf manual.txt manual.ps"
362AC_SUBST(DOCS_OTHER)
363
364HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm"
365AC_SUBST(HTMLFILES)
366
367EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
368AC_SUBST(EXTRA_TEXT)
369
370AC_SUBST_FILE(DESC)
371DESC=desc.txt
372AC_SUBST_FILE(AVENDESC)
373AVENDESC=desc-aven.txt
374AC_SUBST_FILE(SVXEDITDESC)
375SVXEDITDESC=desc-svxedit.txt
376
377dnl Don't define DATADIR if building for MS Windows - it won't be used, and
378dnl can conflict with the DATADIR typedef in objidl.h
379if test no = "$mswindows"; then
380  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
381fi
382
383AC_CONFIG_FILES([make_release], [chmod +x make_release])
384AC_CONFIG_FILES([
385 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
386 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.1
387 doc/version.ent survex.spec src/svxedit lib/survex.keys
388 ])
389AC_OUTPUT
390dnl FIXME update msvc makefile for 1.1 branch
391dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.