source: git/configure.ac @ e34bebc

line_contentsstereotravis-osx
Last change on this file since e34bebc was e34bebc, checked in by Olly Betts <olly@…>, 7 years ago

NEWS,configure.ac: Update for 1.2.7.

  • Property mode set to 100644
File size: 11.8 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.2.7], [http://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2013 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`(
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59)`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_CANONICAL_HOST
64
65dnl Checks for programs.
66AC_PROG_CC
67AC_PROG_CPP
68
69AC_PROG_CXX
70AC_PROG_CXXCPP
71
72AM_PROG_CC_C_O
73
74AC_LANG_C
75
76AC_C_INLINE
77
78AC_EXEEXT
79AC_OBJEXT
80
81mswindows=no
82macosx=no
83case $host_os in
84darwin*) macosx=yes ;;
85*mingw*|*cygwin*|windows*) mswindows=yes ;;
86esac
87
88AC_C_BIGENDIAN
89
90AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
91AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
92
93AC_CHECK_LIB(m, sqrt)
94
95AC_PATH_XTRA
96
97WINPROGS=
98if test yes = "$mswindows"; then
99  WINPROGS='editwrap$(EXEEXT)'
100  AC_MSG_RESULT(building editwrap)
101fi
102AC_SUBST(WINPROGS)
103
104dnl The wxWidgets libraries we need:
105wx_libs="core,gl,html"
106
107AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
108AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
109: ${WX_CONFIG="$WXCONFIG"}
110
111AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
112AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
113
114if test -n "$WX_CONFIG" ; then
115  dnl WX_CONFIG specified - sanity check the value
116  dnl don't check for --ldflags - older wx-config didn't do that
117  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
118    :
119  else
120    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
121  fi
122else
123  if test yes = "$macosx" ; then
124    wxdef=__WXMAC__
125  elif test yes = "$mswindows" ; then
126    wxdef=__WXMSW__
127  else
128    wxdef=__WXGTK__
129  fi
130  dnl See if wx-config exists and is for the correct version.
131  AC_PATH_PROGS(WX_CONFIG, [wx-config])
132  if test -n "$WX_CONFIG" ; then
133    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
134      :
135    else
136      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
137    fi
138  else
139    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
140  fi
141fi
142
143dnl Unless the user has explicitly specified a --unicode setting, prefer
144dnl --unicode=yes if we can get it.
145case $WX_CONFIG in
146  *--unicode=*) ;;
147  *)
148    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
149      WX_CONFIG="$WX_CONFIG --unicode=yes"
150    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
151      WX_CONFIG="$WX_CONFIG --unicode=no"
152    fi ;;
153esac
154
155WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
156dnl Needed for nvidia drivers on linux (for some setups anyway).
157AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
158dnl We use functions from libGLU so always link -lGLU explicitly if it's
159dnl present.
160AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
161dnl We use functions from libGL so always link -lGL explicitly if it's
162dnl present.
163AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
164AC_SUBST(WX_LIBS)
165dnl Mac OS X has OpenGL/gl.h.
166AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
167dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
168AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
169
170dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
171dnl stderr, with nothing to stdout, so just ignore stderr.
172WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
173AC_SUBST(WX_LDFLAGS)
174WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
175AC_SUBST(WX_CFLAGS)
176WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
177AC_SUBST(WX_CXXFLAGS)
178
179AC_LANG_C
180save_CFLAGS=$CFLAGS
181CFLAGS="$CFLAGS $WX_CFLAGS"
182AC_CHECK_SIZEOF([wxChar], [], [
183  #include <wx/defs.h>
184  #if wxCHECK_VERSION(2,9,0)
185  #include <wx/chartype.h>
186  #else
187  #include <wx/wxchar.h>
188  #endif
189])
190CFLAGS=$save_CFLAGS
191
192dnl Check for ffmpeg
193MOVIE_LIBS=
194AC_CHECK_LIB(avcodec, avcodec_init,
195  [AC_CHECK_LIB(avformat, av_register_all,
196    [AC_CHECK_LIB(swscale, sws_scale,
197      [AC_CHECK_LIB(avutil, av_malloc,
198        [AC_CHECK_HEADERS([libavformat/avformat.h],
199          [MOVIE_LIBS="-lswscale -lavformat -lavcodec -lavutil"
200          save_LIBS=$LIBS
201          LIBS="$LIBS $MOVIE_LIBS"
202          AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_open2 avformat_new_stream])
203          AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
204          LIBS=$save_LIBS])],
205        [], [-lavformat -lavcodec -lswscale $WX_LIBS])],
206      [], [-lavformat -lavcodec $WX_LIBS])],
207    [], [-lavcodec $WX_LIBS])
208])
209AC_SUBST(MOVIE_LIBS)
210
211dnl Checks for header files.
212AC_HEADER_STDC
213dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
214AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
215
216dnl Checks for typedefs, structures, and compiler characteristics.
217AC_C_CONST
218AC_TYPE_SIZE_T
219AC_STRUCT_TM
220AC_TYPE_SIGNAL
221
222dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
223dnl if it isn't, assume it is 1000000, as it is on SunOS 4
224AC_TRY_COMPILE([#include <time.h>],[
225#ifndef CLOCKS_PER_SEC
226choke me
227#endif
228], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
229
230dnl Check for 16-bit and 32-bit integer types.
231AC_TYPE_INT16_T
232AC_TYPE_INT32_T
233
234dnl Checks for library functions.
235AC_FUNC_STRFTIME
236if test yes != "$ac_cv_func_strftime"; then
237  AC_LIBOBJ(strftime)
238fi
239AC_FUNC_VPRINTF
240dnl Check if there's a declaration of round().  Below we also check for
241dnl round() with AC_CHECK_FUNCS, which just checks if it can be linked
242dnl against.  Some platforms are missing a prototype for round(), so
243dnl both checks are useful.
244AC_CHECK_DECLS([round], [], [], [[#include <math.h>]])
245dnl check for strcasecmp here as well as below - this one is to get
246dnl HAVE_STRCASECMP defined if appropriate (for img.c)
247AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
248
249dnl difftime seems to be an ANSI invention
250AC_CHECK_FUNCS(difftime)
251
252dnl Much faster than using getc()/putc(), at least on Linux.
253AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
254
255dnl try to find a case-insensitive compare
256
257strcasecmp=no
258dnl The order of these tests is important.
259AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
260if test no = "$strcasecmp"; then
261  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
262fi
263if test no = "$strcasecmp"; then
264  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
265fi
266
267AC_MSG_CHECKING([how to compare strings ignoring case])
268case $strcasecmp in
269no)
270  AC_LIBOBJ(strcasecmp)
271  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
272strcasecmp)
273  AC_MSG_RESULT([strcasecmp]) ;;
274*)
275  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
276    [strcasecmp define for systems which call it something else])
277  AC_MSG_RESULT([$strcasecmp]) ;;
278esac
279
280AC_MSG_CHECKING(for sgmltools v2 or v3)
281if test : != "$SGMLTOOLS" ; then
282  : ${SGMLTOOLS=sgmltools}
283  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
284  *" version 3"*)
285    AC_MSG_RESULT([$SGMLTOOLS]) ;;
286  *" version 2"*)
287    AC_MSG_RESULT([$SGMLTOOLS]) ;;
288  *)
289    SGMLTOOLS="$MISSING sgmltools"
290    AC_MSG_RESULT(not found) ;;
291  esac
292else
293  AC_MSG_RESULT([$SGMLTOOLS])
294fi
295AC_SUBST(SGMLTOOLS)
296AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
297
298AC_MSG_CHECKING(for docbook-to-man)
299if test : != "$DOCBOOK_TO_MAN" ; then
300  : ${DOCBOOK_TO_MAN=docbook-to-man}
301  $DOCBOOK_TO_MAN 2> /dev/null
302  if test $? = 1 ; then
303    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
304  else
305    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
306    AC_MSG_RESULT([not found])
307  fi
308else
309  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
310fi
311AC_SUBST(DOCBOOK_TO_MAN)
312AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
313
314dnl extra warning flags for building with GCC
315if test yes = "$GCC"; then
316  if test yes = "$cross_compiling"; then
317dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
318dnl      -Wwrite-strings -Wcast-align"
319dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
320dnl to disable it for mingw builds.
321    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
322      -Wwrite-strings -Wcast-align"
323    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
324      -Wwrite-strings -Wcast-align -Wno-sign-compare"
325  else
326    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
327      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
328      -Wcast-align"
329    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
330      -Wwrite-strings -Wcast-align"
331  fi
332  dnl too many complaints from headers, etc: -Wconversion
333fi
334AC_SUBST(AM_CFLAGS)
335AC_SUBST(AM_CXXFLAGS)
336
337AC_ARG_ENABLE(profiling,
338[  --enable-profiling Build binaries to generate profiling information],
339[case $enableval in
340  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
341       AM_CFLAGS="$AM_CFLAGS -pg"
342       AC_MSG_RESULT(building binaries to generate profiling information);;
343  no) ;;
344  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
345esac])
346
347HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
348AC_SUBST(HTMLFILES)
349
350EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
351AC_SUBST(EXTRA_TEXT)
352
353AC_SUBST_FILE(DESC)
354DESC=desc.txt
355AC_SUBST_FILE(AVENDESC)
356AVENDESC=desc-aven.txt
357AC_SUBST_FILE(SVXEDITDESC)
358SVXEDITDESC=desc-svxedit.txt
359
360dnl Don't define DATADIR if building for MS Windows - it won't be used, and
361dnl can conflict with the DATADIR typedef in objidl.h
362if test no = "$mswindows"; then
363  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
364fi
365
366AH_BOTTOM(
367[/* Use getc_unlocked() and putc_unlocked() where available, since they are
368 * faster, and we don't multithread file accesses.
369 */
370
371#ifdef HAVE_GETC_UNLOCKED
372# define GETC(F) getc_unlocked(F)
373#else
374# define GETC(F) getc(F)
375#endif
376#ifdef HAVE_PUTC_UNLOCKED
377# define PUTC(C, F) putc_unlocked(C, F)
378#else
379# define PUTC(C, F) putc(C, F)
380#endif
381])
382
383AC_CONFIG_FILES([
384 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
385 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
386 doc/version.ent survex.spec src/svxedit lib/survex.keys lib/Info.plist
387 ])
388AC_OUTPUT
389dnl FIXME update msvc makefile for 1.1 branch
390dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.