source: git/configure.ac @ 6e0cdc2c

add-show-splaysline_contentsstereotravis-osx
Last change on this file since 6e0cdc2c was 6e0cdc2c, checked in by Olly Betts <olly@…>, 8 years ago

Makefile.am,configure.ac: Modern automake seems to cope with files
required by GNU being generated during the build, so we no longer
need to use the "foreign" automake mode. Also use -Werror with
automake.

  • Property mode set to 100644
File size: 11.3 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([src/aven.cc], [1.2.6], [http://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12
13COPYRIGHT_MSG="Copyright (C) 1990-2012 Olly Betts"
14AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
15
16AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
17AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
18                   [Copyright Message for Aven])
19
20AC_SUBST(COPYRIGHT_MSG)
21AC_SUBST(AVEN_COPYRIGHT_MSG)
22
23COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
24AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
25
26AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
27                   [Copyright Message in UTF-8])
28AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
29                   [Copyright Message for Aven in UTF-8])
30
31dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
32PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
33AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
34                   [Name of package (capitalised)])
35AC_SUBST(PRETTYPACKAGE)
36
37dnl set COMMAVERSION to VERSION with the dots replaced by commas -
38dnl e.g. "0,99" or "1,0,22"
39COMMAVERSION=`echo "$VERSION"|tr '.' ','`
40AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
41                   [Version number of package (comma-separated)])
42AC_SUBST(COMMAVERSION)
43
44PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
45AC_ARG_ENABLE(docdir,
46[  --enable-docdir=DIR Set directory for installing documentation to DIR],
47[case $enableval in
48 yes|no)
49  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
50esac
51PKGDOCDIR="$enableval"
52]
53)
54PKGDOCDIR_EXPANDED=`(
55 test NONE = "$prefix" && prefix="$ac_default_prefix"
56 test NONE = "$exec_prefix" && exec_prefix="$prefix"
57 eval echo "$PKGDOCDIR"
58)`
59AC_SUBST(PKGDOCDIR)
60AC_SUBST(PKGDOCDIR_EXPANDED)
61
62AC_ARG_ENABLE(testprogs,
63[  --enable-testprogs Enable building of various test harness programs],
64[case $enableval in
65 yes) TESTPROGS=dump3d ;;
66 no) TESTPROGS= ;;
67 *) AC_MSG_ERROR(bad value $enableval for --enable-testprogs) ;;
68esac
69]
70AC_SUBST(TESTPROGS)
71)
72
73AC_CANONICAL_HOST
74
75dnl Checks for programs.
76AC_PROG_CC
77AC_PROG_CPP
78
79AC_PROG_CXX
80AC_PROG_CXXCPP
81
82AM_PROG_CC_C_O
83
84AC_LANG_C
85
86AC_C_INLINE
87
88AC_EXEEXT
89AC_OBJEXT
90
91mswindows=no
92macosx=no
93case $host_os in
94darwin*) macosx=yes ;;
95*mingw*|*cygwin*|windows*) mswindows=yes ;;
96esac
97
98AC_C_BIGENDIAN
99
100AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
101AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
102
103AC_CHECK_LIB(m, sqrt)
104
105AC_PATH_XTRA
106
107WINPROGS=
108if test yes = "$mswindows"; then
109  WINPROGS='editwrap$(EXEEXT)'
110  AC_MSG_RESULT(building editwrap)
111fi
112AC_SUBST(WINPROGS)
113
114dnl The wxWidgets libraries we need:
115wx_libs="core,gl,html"
116
117AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
118AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
119: ${WX_CONFIG="$WXCONFIG"}
120
121AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
122AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
123
124if test -n "$WX_CONFIG" ; then
125  dnl WX_CONFIG specified - sanity check the value
126  dnl don't check for --ldflags - older wx-config didn't do that
127  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
128    :
129  else
130    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
131  fi
132else
133  if test yes = "$macosx" ; then
134    wxdef=__WXMAC__
135  elif test yes = "$mswindows" ; then
136    wxdef=__WXMSW__
137  else
138    wxdef=__WXGTK__
139  fi
140  dnl See if wx-config exists and is for the correct version.
141  AC_PATH_PROGS(WX_CONFIG, [wx-config])
142  if test -n "$WX_CONFIG" ; then
143    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
144      :
145    else
146      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
147    fi
148  else
149    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
150  fi
151fi
152
153dnl Unless the user has explicitly specified a --unicode setting, prefer
154dnl --unicode=yes if we can get it.
155case $WX_CONFIG in
156  *--unicode=*) ;;
157  *)
158    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
159      WX_CONFIG="$WX_CONFIG --unicode=yes"
160    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
161      WX_CONFIG="$WX_CONFIG --unicode=no"
162    fi ;;
163esac
164
165WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
166dnl Needed for nvidia drivers on linux (for some setups anyway).
167AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
168dnl We use functions from libGLU so always link -lGLU explicitly if it's
169dnl present.
170AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
171dnl We use functions from libGL so always link -lGL explicitly if it's
172dnl present.
173AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
174AC_SUBST(WX_LIBS)
175dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
176AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h])
177
178dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
179dnl stderr, with nothing to stdout, so just ignore stderr.
180WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
181AC_SUBST(WX_LDFLAGS)
182WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
183AC_SUBST(WX_CFLAGS)
184WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
185AC_SUBST(WX_CXXFLAGS)
186
187dnl Check for ffmpeg
188MOVIE_LIBS=
189AC_CHECK_LIB(avcodec, avcodec_init,
190  [AC_CHECK_LIB(avformat, av_register_all,
191    [AC_CHECK_LIB(swscale, sws_scale,
192      [AC_CHECK_LIB(avutil, av_malloc,
193        [AC_CHECK_HEADERS([libavformat/avformat.h],
194          [MOVIE_LIBS="-lswscale -lavformat -lavcodec -lavutil"
195          save_LIBS=$LIBS
196          LIBS="$LIBS $MOVIE_LIBS"
197          AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_open2 avformat_new_stream])
198          AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
199          LIBS=$save_LIBS])],
200        [], [-lavformat -lavcodec -lswscale $WX_LIBS])],
201      [], [-lavformat -lavcodec $WX_LIBS])],
202    [], [-lavcodec $WX_LIBS])
203])
204AC_SUBST(MOVIE_LIBS)
205
206AC_LANG_C
207
208dnl Checks for header files.
209AC_HEADER_STDC
210dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
211AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
212
213dnl Checks for typedefs, structures, and compiler characteristics.
214AC_C_CONST
215AC_TYPE_SIZE_T
216AC_STRUCT_TM
217AC_TYPE_SIGNAL
218
219dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
220dnl if it isn't, assume it is 1000000, as it is on SunOS 4
221AC_TRY_COMPILE([#include <time.h>],[
222#ifndef CLOCKS_PER_SEC
223choke me
224#endif
225], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
226
227dnl Check for 16-bit and 32-bit integer types.
228AC_TYPE_INT16_T
229AC_TYPE_INT32_T
230
231dnl Checks for library functions.
232AC_FUNC_STRFTIME
233if test yes != "$ac_cv_func_strftime"; then
234  AC_LIBOBJ(strftime)
235fi
236AC_FUNC_VPRINTF
237dnl check for strcasecmp here as well as below - this one is to get
238dnl HAVE_STRCASECMP defined if appropriate (for img.c)
239AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
240
241dnl difftime seems to be an ANSI invention
242AC_CHECK_FUNCS(difftime)
243
244dnl Much faster than using getc()/putc(), at least on Linux.
245AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
246
247dnl try to find a case-insensitive compare
248
249strcasecmp=no
250dnl The order of these tests is important.
251AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
252if test no = "$strcasecmp"; then
253  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
254fi
255if test no = "$strcasecmp"; then
256  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
257fi
258
259AC_MSG_CHECKING([how to compare strings ignoring case])
260case $strcasecmp in
261no)
262  AC_LIBOBJ(strcasecmp)
263  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
264strcasecmp)
265  AC_MSG_RESULT([strcasecmp]) ;;
266*)
267  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
268    [strcasecmp define for systems which call it something else])
269  AC_MSG_RESULT([$strcasecmp]) ;;
270esac
271
272AC_MSG_CHECKING(for sgmltools v2 or v3)
273if test : != "$SGMLTOOLS" ; then
274  : ${SGMLTOOLS=sgmltools}
275  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
276  *" version 3"*)
277    AC_MSG_RESULT([$SGMLTOOLS]) ;;
278  *" version 2"*)
279    AC_MSG_RESULT([$SGMLTOOLS]) ;;
280  *)
281    SGMLTOOLS="$MISSING sgmltools"
282    AC_MSG_RESULT(not found) ;;
283  esac
284else
285  AC_MSG_RESULT([$SGMLTOOLS])
286fi
287AC_SUBST(SGMLTOOLS)
288AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
289
290AC_MSG_CHECKING(for docbook-to-man)
291if test : != "$DOCBOOK_TO_MAN" ; then
292  : ${DOCBOOK_TO_MAN=docbook-to-man}
293  $DOCBOOK_TO_MAN 2> /dev/null
294  if test $? = 1 ; then
295    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
296  else
297    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
298    AC_MSG_RESULT([not found])
299  fi
300else
301  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
302fi
303AC_SUBST(DOCBOOK_TO_MAN)
304AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
305
306dnl extra warning flags for building with GCC
307if test yes = "$GCC"; then
308  if test yes = "$cross_compiling"; then
309dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
310dnl      -Wwrite-strings -Wcast-align"
311dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
312dnl to disable it for mingw builds.
313    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
314      -Wwrite-strings -Wcast-align"
315    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
316      -Wwrite-strings -Wcast-align -Wno-sign-compare"
317  else
318    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
319      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
320      -Wcast-align"
321    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
322      -Wwrite-strings -Wcast-align"
323  fi
324  dnl too many complaints from headers, etc: -Wconversion
325fi
326AC_SUBST(AM_CFLAGS)
327AC_SUBST(AM_CXXFLAGS)
328
329AC_ARG_ENABLE(profiling,
330[  --enable-profiling Build binaries to generate profiling information],
331[case $enableval in
332  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
333       AM_CFLAGS="$AM_CFLAGS -pg"
334       AC_MSG_RESULT(building binaries to generate profiling information);;
335  no) ;;
336  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
337esac])
338
339HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm"
340AC_SUBST(HTMLFILES)
341
342EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
343AC_SUBST(EXTRA_TEXT)
344
345AC_SUBST_FILE(DESC)
346DESC=desc.txt
347AC_SUBST_FILE(AVENDESC)
348AVENDESC=desc-aven.txt
349AC_SUBST_FILE(SVXEDITDESC)
350SVXEDITDESC=desc-svxedit.txt
351
352dnl Don't define DATADIR if building for MS Windows - it won't be used, and
353dnl can conflict with the DATADIR typedef in objidl.h
354if test no = "$mswindows"; then
355  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
356fi
357
358AH_BOTTOM(
359[/* Use getc_unlocked() and putc_unlocked() where available, since they are
360 * faster, and we don't multithread file accesses.
361 */
362
363#ifdef HAVE_GETC_UNLOCKED
364# define GETC(F) getc_unlocked(F)
365#else
366# define GETC(F) getc(F)
367#endif
368#ifdef HAVE_PUTC_UNLOCKED
369# define PUTC(C, F) putc_unlocked(C, F)
370#else
371# define PUTC(C, F) putc(C, F)
372#endif
373])
374
375AC_CONFIG_FILES([
376 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
377 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
378 doc/version.ent survex.spec src/svxedit lib/survex.keys lib/Info.plist
379 ])
380AC_OUTPUT
381dnl FIXME update msvc makefile for 1.1 branch
382dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.