source: git/configure.ac @ 5b7b184

add-show-splaysline_contentsstereotravis-osx
Last change on this file since 5b7b184 was 5b7b184, checked in by Olly Betts <olly@…>, 8 years ago

configure.ac: Fix package name, broken during modernisation of
autotools use.

  • Property mode set to 100644
File size: 11.4 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.2.6], [http://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2012 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`(
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59)`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_ARG_ENABLE(testprogs,
64[  --enable-testprogs Enable building of various test harness programs],
65[case $enableval in
66 yes) TESTPROGS=dump3d ;;
67 no) TESTPROGS= ;;
68 *) AC_MSG_ERROR(bad value $enableval for --enable-testprogs) ;;
69esac
70]
71AC_SUBST(TESTPROGS)
72)
73
74AC_CANONICAL_HOST
75
76dnl Checks for programs.
77AC_PROG_CC
78AC_PROG_CPP
79
80AC_PROG_CXX
81AC_PROG_CXXCPP
82
83AM_PROG_CC_C_O
84
85AC_LANG_C
86
87AC_C_INLINE
88
89AC_EXEEXT
90AC_OBJEXT
91
92mswindows=no
93macosx=no
94case $host_os in
95darwin*) macosx=yes ;;
96*mingw*|*cygwin*|windows*) mswindows=yes ;;
97esac
98
99AC_C_BIGENDIAN
100
101AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
102AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
103
104AC_CHECK_LIB(m, sqrt)
105
106AC_PATH_XTRA
107
108WINPROGS=
109if test yes = "$mswindows"; then
110  WINPROGS='editwrap$(EXEEXT)'
111  AC_MSG_RESULT(building editwrap)
112fi
113AC_SUBST(WINPROGS)
114
115dnl The wxWidgets libraries we need:
116wx_libs="core,gl,html"
117
118AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
119AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
120: ${WX_CONFIG="$WXCONFIG"}
121
122AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
123AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
124
125if test -n "$WX_CONFIG" ; then
126  dnl WX_CONFIG specified - sanity check the value
127  dnl don't check for --ldflags - older wx-config didn't do that
128  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
129    :
130  else
131    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
132  fi
133else
134  if test yes = "$macosx" ; then
135    wxdef=__WXMAC__
136  elif test yes = "$mswindows" ; then
137    wxdef=__WXMSW__
138  else
139    wxdef=__WXGTK__
140  fi
141  dnl See if wx-config exists and is for the correct version.
142  AC_PATH_PROGS(WX_CONFIG, [wx-config])
143  if test -n "$WX_CONFIG" ; then
144    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
145      :
146    else
147      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
148    fi
149  else
150    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
151  fi
152fi
153
154dnl Unless the user has explicitly specified a --unicode setting, prefer
155dnl --unicode=yes if we can get it.
156case $WX_CONFIG in
157  *--unicode=*) ;;
158  *)
159    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
160      WX_CONFIG="$WX_CONFIG --unicode=yes"
161    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
162      WX_CONFIG="$WX_CONFIG --unicode=no"
163    fi ;;
164esac
165
166WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
167dnl Needed for nvidia drivers on linux (for some setups anyway).
168AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
169dnl We use functions from libGLU so always link -lGLU explicitly if it's
170dnl present.
171AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
172dnl We use functions from libGL so always link -lGL explicitly if it's
173dnl present.
174AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
175AC_SUBST(WX_LIBS)
176dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
177AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h])
178
179dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
180dnl stderr, with nothing to stdout, so just ignore stderr.
181WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
182AC_SUBST(WX_LDFLAGS)
183WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
184AC_SUBST(WX_CFLAGS)
185WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
186AC_SUBST(WX_CXXFLAGS)
187
188dnl Check for ffmpeg
189MOVIE_LIBS=
190AC_CHECK_LIB(avcodec, avcodec_init,
191  [AC_CHECK_LIB(avformat, av_register_all,
192    [AC_CHECK_LIB(swscale, sws_scale,
193      [AC_CHECK_LIB(avutil, av_malloc,
194        [AC_CHECK_HEADERS([libavformat/avformat.h],
195          [MOVIE_LIBS="-lswscale -lavformat -lavcodec -lavutil"
196          save_LIBS=$LIBS
197          LIBS="$LIBS $MOVIE_LIBS"
198          AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_open2 avformat_new_stream])
199          AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
200          LIBS=$save_LIBS])],
201        [], [-lavformat -lavcodec -lswscale $WX_LIBS])],
202      [], [-lavformat -lavcodec $WX_LIBS])],
203    [], [-lavcodec $WX_LIBS])
204])
205AC_SUBST(MOVIE_LIBS)
206
207AC_LANG_C
208
209dnl Checks for header files.
210AC_HEADER_STDC
211dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
212AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
213
214dnl Checks for typedefs, structures, and compiler characteristics.
215AC_C_CONST
216AC_TYPE_SIZE_T
217AC_STRUCT_TM
218AC_TYPE_SIGNAL
219
220dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
221dnl if it isn't, assume it is 1000000, as it is on SunOS 4
222AC_TRY_COMPILE([#include <time.h>],[
223#ifndef CLOCKS_PER_SEC
224choke me
225#endif
226], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
227
228dnl Check for 16-bit and 32-bit integer types.
229AC_TYPE_INT16_T
230AC_TYPE_INT32_T
231
232dnl Checks for library functions.
233AC_FUNC_STRFTIME
234if test yes != "$ac_cv_func_strftime"; then
235  AC_LIBOBJ(strftime)
236fi
237AC_FUNC_VPRINTF
238dnl check for strcasecmp here as well as below - this one is to get
239dnl HAVE_STRCASECMP defined if appropriate (for img.c)
240AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
241
242dnl difftime seems to be an ANSI invention
243AC_CHECK_FUNCS(difftime)
244
245dnl Much faster than using getc()/putc(), at least on Linux.
246AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
247
248dnl try to find a case-insensitive compare
249
250strcasecmp=no
251dnl The order of these tests is important.
252AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
253if test no = "$strcasecmp"; then
254  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
255fi
256if test no = "$strcasecmp"; then
257  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
258fi
259
260AC_MSG_CHECKING([how to compare strings ignoring case])
261case $strcasecmp in
262no)
263  AC_LIBOBJ(strcasecmp)
264  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
265strcasecmp)
266  AC_MSG_RESULT([strcasecmp]) ;;
267*)
268  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
269    [strcasecmp define for systems which call it something else])
270  AC_MSG_RESULT([$strcasecmp]) ;;
271esac
272
273AC_MSG_CHECKING(for sgmltools v2 or v3)
274if test : != "$SGMLTOOLS" ; then
275  : ${SGMLTOOLS=sgmltools}
276  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
277  *" version 3"*)
278    AC_MSG_RESULT([$SGMLTOOLS]) ;;
279  *" version 2"*)
280    AC_MSG_RESULT([$SGMLTOOLS]) ;;
281  *)
282    SGMLTOOLS="$MISSING sgmltools"
283    AC_MSG_RESULT(not found) ;;
284  esac
285else
286  AC_MSG_RESULT([$SGMLTOOLS])
287fi
288AC_SUBST(SGMLTOOLS)
289AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
290
291AC_MSG_CHECKING(for docbook-to-man)
292if test : != "$DOCBOOK_TO_MAN" ; then
293  : ${DOCBOOK_TO_MAN=docbook-to-man}
294  $DOCBOOK_TO_MAN 2> /dev/null
295  if test $? = 1 ; then
296    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
297  else
298    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
299    AC_MSG_RESULT([not found])
300  fi
301else
302  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
303fi
304AC_SUBST(DOCBOOK_TO_MAN)
305AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
306
307dnl extra warning flags for building with GCC
308if test yes = "$GCC"; then
309  if test yes = "$cross_compiling"; then
310dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
311dnl      -Wwrite-strings -Wcast-align"
312dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
313dnl to disable it for mingw builds.
314    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
315      -Wwrite-strings -Wcast-align"
316    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
317      -Wwrite-strings -Wcast-align -Wno-sign-compare"
318  else
319    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
320      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
321      -Wcast-align"
322    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
323      -Wwrite-strings -Wcast-align"
324  fi
325  dnl too many complaints from headers, etc: -Wconversion
326fi
327AC_SUBST(AM_CFLAGS)
328AC_SUBST(AM_CXXFLAGS)
329
330AC_ARG_ENABLE(profiling,
331[  --enable-profiling Build binaries to generate profiling information],
332[case $enableval in
333  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
334       AM_CFLAGS="$AM_CFLAGS -pg"
335       AC_MSG_RESULT(building binaries to generate profiling information);;
336  no) ;;
337  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
338esac])
339
340HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm"
341AC_SUBST(HTMLFILES)
342
343EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
344AC_SUBST(EXTRA_TEXT)
345
346AC_SUBST_FILE(DESC)
347DESC=desc.txt
348AC_SUBST_FILE(AVENDESC)
349AVENDESC=desc-aven.txt
350AC_SUBST_FILE(SVXEDITDESC)
351SVXEDITDESC=desc-svxedit.txt
352
353dnl Don't define DATADIR if building for MS Windows - it won't be used, and
354dnl can conflict with the DATADIR typedef in objidl.h
355if test no = "$mswindows"; then
356  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
357fi
358
359AH_BOTTOM(
360[/* Use getc_unlocked() and putc_unlocked() where available, since they are
361 * faster, and we don't multithread file accesses.
362 */
363
364#ifdef HAVE_GETC_UNLOCKED
365# define GETC(F) getc_unlocked(F)
366#else
367# define GETC(F) getc(F)
368#endif
369#ifdef HAVE_PUTC_UNLOCKED
370# define PUTC(C, F) putc_unlocked(C, F)
371#else
372# define PUTC(C, F) putc(C, F)
373#endif
374])
375
376AC_CONFIG_FILES([
377 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
378 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
379 doc/version.ent survex.spec src/svxedit lib/survex.keys lib/Info.plist
380 ])
381AC_OUTPUT
382dnl FIXME update msvc makefile for 1.1 branch
383dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.