source: git/configure.ac @ 55ee200

line_contentsstereotravis-osx last-good
Last change on this file since 55ee200 was 55ee200, checked in by Olly Betts <olly@…>, 8 years ago

configure.ac: Update copyright date.

  • Property mode set to 100644
File size: 12.0 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.2.6], [http://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2013 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`(
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59)`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_ARG_ENABLE(testprogs,
64[  --enable-testprogs Enable building of various test harness programs],
65[case $enableval in
66 yes) TESTPROGS=dump3d ;;
67 no) TESTPROGS= ;;
68 *) AC_MSG_ERROR(bad value $enableval for --enable-testprogs) ;;
69esac
70]
71AC_SUBST(TESTPROGS)
72)
73
74AC_CANONICAL_HOST
75
76dnl Checks for programs.
77AC_PROG_CC
78AC_PROG_CPP
79
80AC_PROG_CXX
81AC_PROG_CXXCPP
82
83AM_PROG_CC_C_O
84
85AC_LANG_C
86
87AC_C_INLINE
88
89AC_EXEEXT
90AC_OBJEXT
91
92mswindows=no
93macosx=no
94case $host_os in
95darwin*) macosx=yes ;;
96*mingw*|*cygwin*|windows*) mswindows=yes ;;
97esac
98
99AC_C_BIGENDIAN
100
101AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
102AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
103
104AC_CHECK_LIB(m, sqrt)
105
106AC_PATH_XTRA
107
108WINPROGS=
109if test yes = "$mswindows"; then
110  WINPROGS='editwrap$(EXEEXT)'
111  AC_MSG_RESULT(building editwrap)
112fi
113AC_SUBST(WINPROGS)
114
115dnl The wxWidgets libraries we need:
116wx_libs="core,gl,html"
117
118AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
119AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
120: ${WX_CONFIG="$WXCONFIG"}
121
122AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
123AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
124
125if test -n "$WX_CONFIG" ; then
126  dnl WX_CONFIG specified - sanity check the value
127  dnl don't check for --ldflags - older wx-config didn't do that
128  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
129    :
130  else
131    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
132  fi
133else
134  if test yes = "$macosx" ; then
135    wxdef=__WXMAC__
136  elif test yes = "$mswindows" ; then
137    wxdef=__WXMSW__
138  else
139    wxdef=__WXGTK__
140  fi
141  dnl See if wx-config exists and is for the correct version.
142  AC_PATH_PROGS(WX_CONFIG, [wx-config])
143  if test -n "$WX_CONFIG" ; then
144    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
145      :
146    else
147      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
148    fi
149  else
150    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
151  fi
152fi
153
154dnl Unless the user has explicitly specified a --unicode setting, prefer
155dnl --unicode=yes if we can get it.
156case $WX_CONFIG in
157  *--unicode=*) ;;
158  *)
159    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
160      WX_CONFIG="$WX_CONFIG --unicode=yes"
161    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
162      WX_CONFIG="$WX_CONFIG --unicode=no"
163    fi ;;
164esac
165
166WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
167dnl Needed for nvidia drivers on linux (for some setups anyway).
168AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
169dnl We use functions from libGLU so always link -lGLU explicitly if it's
170dnl present.
171AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
172dnl We use functions from libGL so always link -lGL explicitly if it's
173dnl present.
174AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
175AC_SUBST(WX_LIBS)
176dnl Mac OS X has OpenGL/gl.h.
177AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
178dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
179AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
180
181dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
182dnl stderr, with nothing to stdout, so just ignore stderr.
183WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
184AC_SUBST(WX_LDFLAGS)
185WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
186AC_SUBST(WX_CFLAGS)
187WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
188AC_SUBST(WX_CXXFLAGS)
189
190AC_LANG_C
191save_CFLAGS=$CFLAGS
192CFLAGS="$CFLAGS $WX_CFLAGS"
193AC_CHECK_SIZEOF([wxChar], [], [
194  #include <wx/defs.h>
195  #if wxCHECK_VERSION(2,9,0)
196  #include <wx/chartype.h>
197  #else
198  #include <wx/wxchar.h>
199  #endif
200])
201CFLAGS=$save_CFLAGS
202
203dnl Check for ffmpeg
204MOVIE_LIBS=
205AC_CHECK_LIB(avcodec, avcodec_init,
206  [AC_CHECK_LIB(avformat, av_register_all,
207    [AC_CHECK_LIB(swscale, sws_scale,
208      [AC_CHECK_LIB(avutil, av_malloc,
209        [AC_CHECK_HEADERS([libavformat/avformat.h],
210          [MOVIE_LIBS="-lswscale -lavformat -lavcodec -lavutil"
211          save_LIBS=$LIBS
212          LIBS="$LIBS $MOVIE_LIBS"
213          AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_open2 avformat_new_stream])
214          AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
215          LIBS=$save_LIBS])],
216        [], [-lavformat -lavcodec -lswscale $WX_LIBS])],
217      [], [-lavformat -lavcodec $WX_LIBS])],
218    [], [-lavcodec $WX_LIBS])
219])
220AC_SUBST(MOVIE_LIBS)
221
222dnl Checks for header files.
223AC_HEADER_STDC
224dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
225AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
226
227dnl Checks for typedefs, structures, and compiler characteristics.
228AC_C_CONST
229AC_TYPE_SIZE_T
230AC_STRUCT_TM
231AC_TYPE_SIGNAL
232
233dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
234dnl if it isn't, assume it is 1000000, as it is on SunOS 4
235AC_TRY_COMPILE([#include <time.h>],[
236#ifndef CLOCKS_PER_SEC
237choke me
238#endif
239], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
240
241dnl Check for 16-bit and 32-bit integer types.
242AC_TYPE_INT16_T
243AC_TYPE_INT32_T
244
245dnl Checks for library functions.
246AC_FUNC_STRFTIME
247if test yes != "$ac_cv_func_strftime"; then
248  AC_LIBOBJ(strftime)
249fi
250AC_FUNC_VPRINTF
251dnl Check if there's a declaration of round().  Below we also check for
252dnl round() with AC_CHECK_FUNCS, which just checks if it can be linked
253dnl against.  Some platforms are missing a prototype for round(), so
254dnl both checks are useful.
255AC_CHECK_DECLS([round], [], [], [[#include <math.h>]])
256dnl check for strcasecmp here as well as below - this one is to get
257dnl HAVE_STRCASECMP defined if appropriate (for img.c)
258AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
259
260dnl difftime seems to be an ANSI invention
261AC_CHECK_FUNCS(difftime)
262
263dnl Much faster than using getc()/putc(), at least on Linux.
264AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
265
266dnl try to find a case-insensitive compare
267
268strcasecmp=no
269dnl The order of these tests is important.
270AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
271if test no = "$strcasecmp"; then
272  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
273fi
274if test no = "$strcasecmp"; then
275  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
276fi
277
278AC_MSG_CHECKING([how to compare strings ignoring case])
279case $strcasecmp in
280no)
281  AC_LIBOBJ(strcasecmp)
282  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
283strcasecmp)
284  AC_MSG_RESULT([strcasecmp]) ;;
285*)
286  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
287    [strcasecmp define for systems which call it something else])
288  AC_MSG_RESULT([$strcasecmp]) ;;
289esac
290
291AC_MSG_CHECKING(for sgmltools v2 or v3)
292if test : != "$SGMLTOOLS" ; then
293  : ${SGMLTOOLS=sgmltools}
294  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
295  *" version 3"*)
296    AC_MSG_RESULT([$SGMLTOOLS]) ;;
297  *" version 2"*)
298    AC_MSG_RESULT([$SGMLTOOLS]) ;;
299  *)
300    SGMLTOOLS="$MISSING sgmltools"
301    AC_MSG_RESULT(not found) ;;
302  esac
303else
304  AC_MSG_RESULT([$SGMLTOOLS])
305fi
306AC_SUBST(SGMLTOOLS)
307AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
308
309AC_MSG_CHECKING(for docbook-to-man)
310if test : != "$DOCBOOK_TO_MAN" ; then
311  : ${DOCBOOK_TO_MAN=docbook-to-man}
312  $DOCBOOK_TO_MAN 2> /dev/null
313  if test $? = 1 ; then
314    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
315  else
316    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
317    AC_MSG_RESULT([not found])
318  fi
319else
320  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
321fi
322AC_SUBST(DOCBOOK_TO_MAN)
323AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
324
325dnl extra warning flags for building with GCC
326if test yes = "$GCC"; then
327  if test yes = "$cross_compiling"; then
328dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
329dnl      -Wwrite-strings -Wcast-align"
330dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
331dnl to disable it for mingw builds.
332    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
333      -Wwrite-strings -Wcast-align"
334    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
335      -Wwrite-strings -Wcast-align -Wno-sign-compare"
336  else
337    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
338      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
339      -Wcast-align"
340    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
341      -Wwrite-strings -Wcast-align"
342  fi
343  dnl too many complaints from headers, etc: -Wconversion
344fi
345AC_SUBST(AM_CFLAGS)
346AC_SUBST(AM_CXXFLAGS)
347
348AC_ARG_ENABLE(profiling,
349[  --enable-profiling Build binaries to generate profiling information],
350[case $enableval in
351  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
352       AM_CFLAGS="$AM_CFLAGS -pg"
353       AC_MSG_RESULT(building binaries to generate profiling information);;
354  no) ;;
355  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
356esac])
357
358HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm"
359AC_SUBST(HTMLFILES)
360
361EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
362AC_SUBST(EXTRA_TEXT)
363
364AC_SUBST_FILE(DESC)
365DESC=desc.txt
366AC_SUBST_FILE(AVENDESC)
367AVENDESC=desc-aven.txt
368AC_SUBST_FILE(SVXEDITDESC)
369SVXEDITDESC=desc-svxedit.txt
370
371dnl Don't define DATADIR if building for MS Windows - it won't be used, and
372dnl can conflict with the DATADIR typedef in objidl.h
373if test no = "$mswindows"; then
374  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
375fi
376
377AH_BOTTOM(
378[/* Use getc_unlocked() and putc_unlocked() where available, since they are
379 * faster, and we don't multithread file accesses.
380 */
381
382#ifdef HAVE_GETC_UNLOCKED
383# define GETC(F) getc_unlocked(F)
384#else
385# define GETC(F) getc(F)
386#endif
387#ifdef HAVE_PUTC_UNLOCKED
388# define PUTC(C, F) putc_unlocked(C, F)
389#else
390# define PUTC(C, F) putc(C, F)
391#endif
392])
393
394AC_CONFIG_FILES([
395 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
396 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
397 doc/version.ent survex.spec src/svxedit lib/survex.keys lib/Info.plist
398 ])
399AC_OUTPUT
400dnl FIXME update msvc makefile for 1.1 branch
401dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.