source: git/configure.ac @ 040c02e

RELEASE/1.2debug-cidebug-ci-sanitiserswalls-data
Last change on this file since 040c02e was 040c02e, checked in by Olly Betts <olly@…>, 5 years ago

Update for 1.2.42

  • Property mode set to 100644
File size: 12.3 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.2.42], [https://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2018 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`(
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59)`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_CANONICAL_HOST
64
65dnl Checks for programs.
66AC_PROG_CC
67AC_PROG_CPP
68
69AC_PROG_CXX
70AC_PROG_CXXCPP
71
72dnl Probe for any options needed to enable C++11 support.
73AX_CXX_COMPILE_STDCXX_11
74
75AM_PROG_CC_C_O
76
77AC_LANG_C
78
79AC_C_INLINE
80
81AC_EXEEXT
82AC_OBJEXT
83
84mswindows=no
85macos=no
86case $host_os in
87darwin*) macos=yes ;;
88*mingw*|*cygwin*|windows*) mswindows=yes ;;
89esac
90
91AC_C_BIGENDIAN
92
93AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
94AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
95
96AC_CHECK_LIB(m, sqrt)
97
98AC_PATH_XTRA
99
100dnl The wxWidgets libraries we need:
101wx_libs="core,gl,html"
102
103AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
104AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
105: ${WX_CONFIG="$WXCONFIG"}
106
107AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
108AM_CONDITIONAL(MACOS, [test yes = "$macos"])
109
110if test -n "$WX_CONFIG" ; then
111  dnl WX_CONFIG specified - sanity check the value
112  dnl don't check for --ldflags - older wx-config didn't do that
113  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
114    :
115  else
116    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
117  fi
118else
119  if test yes = "$macos" ; then
120    wxdef=__WXMAC__
121  elif test yes = "$mswindows" ; then
122    wxdef=__WXMSW__
123  else
124    wxdef=__WXGTK__
125  fi
126  dnl See if wx-config exists and is for the correct version.
127  dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
128  dnl preference.
129  AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config])
130  if test -n "$WX_CONFIG" ; then
131    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
132      :
133    else
134      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
135    fi
136  else
137    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
138  fi
139fi
140
141dnl Unless the user has explicitly specified a --unicode setting, prefer
142dnl --unicode=yes if we can get it.
143case $WX_CONFIG in
144  *--unicode=*) ;;
145  *)
146    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
147      WX_CONFIG="$WX_CONFIG --unicode=yes"
148    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
149      WX_CONFIG="$WX_CONFIG --unicode=no"
150    fi ;;
151esac
152
153WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
154dnl Needed for nvidia drivers on linux (for some setups anyway).
155AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
156dnl We use functions from libGLU so always link -lGLU explicitly if it's
157dnl present.
158AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
159dnl We use functions from libGL so always link -lGL explicitly if it's
160dnl present.
161AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
162AC_SUBST(WX_LIBS)
163dnl macOS has OpenGL/gl.h.
164AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
165dnl The Debian mingw-w64 packages lack GL/glext.h; macOS has OpenGL/glext.h.
166AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
167
168WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
169AC_SUBST(WX_CFLAGS)
170WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
171AC_SUBST(WX_CXXFLAGS)
172
173AC_LANG_C
174save_CFLAGS=$CFLAGS
175CFLAGS="$CFLAGS $WX_CFLAGS"
176AC_CHECK_SIZEOF([wxChar], [], [
177  #include <wx/defs.h>
178  #include <wx/chartype.h>
179])
180CFLAGS=$save_CFLAGS
181
182dnl Check for libav (FIXME: does our code still work with ffmpeg?)
183PKG_CHECK_MODULES([LIBAV], [libavcodec libavformat libswscale libavutil], [
184  AC_DEFINE([WITH_LIBAV], [1], [Use libav for movie export])
185  save_CXXFLAGS=$CXXFLAGS
186  save_LIBS=$LIBS
187  CFLAGS="$CFLAGS $LIBAV_CFLAGS"
188  LIBS="$LIBS $LIBAV_LIBS"
189  AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
190  AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
191  AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
192  AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
193  AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
194  CXXFLAGS=$save_CXXFLAGS
195  LIBS=$save_LIBS
196], [
197  dnl Build without movie export feature.
198])
199AC_SUBST([LIBAV_LIBS])
200AC_SUBST([LIBAV_CFLAGS])
201
202dnl Check for PROJ4
203PKG_CHECK_MODULES([PROJ], [proj], [
204], [
205  dnl pkg-config support in proj seems quite new, so probe directly if not
206  dnl found.
207  AC_CHECK_LIB([proj], [pj_init_plus], [
208      PROJ_LIBS=-lproj
209      PROJ_CFLAGS=
210    ], [
211      AC_MSG_ERROR([PROJ4 required for coordinate transformations])
212    ])
213])
214AC_SUBST([PROJ_LIBS])
215AC_SUBST([PROJ_CFLAGS])
216dnl Check for new-style PROJ header.
217AC_CHECK_HEADERS([proj.h])
218
219dnl Checks for header files.
220AC_HEADER_STDC
221dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
222AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
223
224dnl Checks for typedefs, structures, and compiler characteristics.
225AC_TYPE_SIZE_T
226AC_STRUCT_TM
227AC_TYPE_SIGNAL
228
229dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
230dnl if it isn't, assume it is 1000000, as it is on SunOS 4
231AC_TRY_COMPILE([#include <time.h>],[
232#ifndef CLOCKS_PER_SEC
233choke me
234#endif
235], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
236
237dnl Check for 16-bit and 32-bit integer types.
238AC_TYPE_INT16_T
239AC_TYPE_INT32_T
240
241dnl Checks for library functions.
242AC_FUNC_STRFTIME
243if test yes != "$ac_cv_func_strftime"; then
244  AC_LIBOBJ(strftime)
245fi
246AC_FUNC_VPRINTF
247dnl Check if there's a declaration of lround().  Below we also check for
248dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
249dnl against.  Some platforms are missing a prototype for lround(), so
250dnl both checks are useful.
251AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
252dnl check for strcasecmp here as well as below - this one is to get
253dnl HAVE_STRCASECMP defined if appropriate (for img.c)
254AC_CHECK_FUNCS([popen getpwuid lround strcasecmp hypot mmap])
255
256dnl difftime seems to be an ANSI invention
257AC_CHECK_FUNCS(difftime)
258
259dnl Much faster than using getc()/putc(), at least on Linux.
260AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
261
262AC_CHECK_FUNCS([setenv unsetenv])
263
264dnl try to find a case-insensitive compare
265
266strcasecmp=no
267dnl The order of these tests is important.
268AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
269if test no = "$strcasecmp"; then
270  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
271fi
272if test no = "$strcasecmp"; then
273  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
274fi
275
276AC_MSG_CHECKING([how to compare strings ignoring case])
277case $strcasecmp in
278no)
279  AC_LIBOBJ(strcasecmp)
280  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
281strcasecmp)
282  AC_MSG_RESULT([strcasecmp]) ;;
283*)
284  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
285    [strcasecmp define for systems which call it something else])
286  AC_MSG_RESULT([$strcasecmp]) ;;
287esac
288
289AC_MSG_CHECKING(for sgmltools v2 or v3)
290if test : != "$SGMLTOOLS" ; then
291  : ${SGMLTOOLS=sgmltools}
292  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
293  *" version 3"*)
294    AC_MSG_RESULT([$SGMLTOOLS]) ;;
295  *" version 2"*)
296    AC_MSG_RESULT([$SGMLTOOLS]) ;;
297  *)
298    SGMLTOOLS="$MISSING sgmltools"
299    AC_MSG_RESULT(not found) ;;
300  esac
301else
302  AC_MSG_RESULT([$SGMLTOOLS])
303fi
304AC_SUBST(SGMLTOOLS)
305AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
306
307AC_MSG_CHECKING(for docbook2man)
308if test : != "$DOCBOOK2MAN" ; then
309  : ${DOCBOOK2MAN=docbook2man}
310  $DOCBOOK2MAN 2> /dev/null
311  if test $? = 1 ; then
312    AC_MSG_RESULT([$DOCBOOK2MAN])
313  else
314    DOCBOOK2MAN="$MISSING docbook2man"
315    AC_MSG_RESULT([not found])
316  fi
317else
318  AC_MSG_RESULT([$DOCBOOK2MAN])
319fi
320AC_SUBST(DOCBOOK2MAN)
321AC_ARG_VAR(DOCBOOK2MAN, [docbook2man command])
322
323dnl extra warning flags for building with GCC
324if test yes = "$GCC"; then
325  if test yes = "$cross_compiling"; then
326dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
327dnl      -Wwrite-strings -Wcast-align"
328dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
329dnl to disable it for mingw builds.
330    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
331      -Wwrite-strings -Wcast-align"
332    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
333      -Wwrite-strings -Wcast-align -Wno-sign-compare"
334  else
335    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
336      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
337      -Wcast-align"
338    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
339      -Wwrite-strings -Wcast-align"
340  fi
341  dnl too many complaints from headers, etc: -Wconversion
342fi
343AC_SUBST(AM_CFLAGS)
344AC_SUBST(AM_CXXFLAGS)
345
346dnl See if large file support is available.  Survex is unlikely to need to
347dnl process files > 2GB in size, but LFS is also needed for stat() to work
348dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
349AC_SYS_LARGEFILE
350
351AC_ARG_ENABLE(profiling,
352[  --enable-profiling Build binaries to generate profiling information],
353[case $enableval in
354  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
355       AM_CFLAGS="$AM_CFLAGS -pg"
356       AC_MSG_RESULT(building binaries to generate profiling information);;
357  no) ;;
358  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
359esac])
360
361HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
362AC_SUBST(HTMLFILES)
363
364EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
365AC_SUBST(EXTRA_TEXT)
366
367AC_SUBST_FILE(DESC)
368DESC=desc.txt
369AC_SUBST_FILE(AVENDESC)
370AVENDESC=desc-aven.txt
371
372dnl Don't define DATADIR if building for MS Windows - it won't be used, and
373dnl can conflict with the DATADIR typedef in objidl.h
374if test no = "$mswindows"; then
375  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
376fi
377
378AH_BOTTOM(
379[/* Use getc_unlocked() and putc_unlocked() where available, since they are
380 * faster, and we don't multithread file accesses.
381 */
382
383#ifdef HAVE_GETC_UNLOCKED
384# define GETC(F) getc_unlocked(F)
385#else
386# define GETC(F) getc(F)
387#endif
388#ifdef HAVE_PUTC_UNLOCKED
389# define PUTC(C, F) putc_unlocked(C, F)
390#else
391# define PUTC(C, F) putc(C, F)
392#endif
393])
394
395AC_CONFIG_FILES([
396 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
397 lib/images/Makefile
398 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
399 survex.spec lib/Info.plist
400 ])
401AC_OUTPUT
402dnl FIXME update msvc makefile for 1.2 branch
403dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.