source: git/configure.in @ da83c18

RELEASE/1.0
Last change on this file since da83c18 was da83c18, checked in by Olly Betts <olly@…>, 13 years ago

Backport change from 1.2.0:
configure.in,survex.spec.in: Default to installing docs into
/usr/share/doc/survex rather than /usr/doc/survex.

git-svn-id: file:///home/survex-svn/survex/branches/1.0@3690 4b37db11-9a0c-4f06-9ece-9ab7cdaee568

  • Property mode set to 100644
File size: 11.6 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl CFLAGS=-DDEFAULTLANG=fr to build with French as the default language.
4
5dnl Need autoconf 2.13 or later for 3 argument version of AC_DEFINE
6dnl Need autoconf 2.50 or later for AC_ARG_VAR
7AC_PREREQ(2.50)
8AC_INIT(src/cavern.c)
9
10AM_INIT_AUTOMAKE(survex, 1.0.40)
11RELEASE=1
12
13AC_SUBST(RELEASE)
14AM_CONFIG_HEADER(config.h)
15
16dnl don't reformat the next line, miniam.pl pulls out the value
17COPYRIGHT_MSG="Copyright (C) 1990-2008,2010 Olly Betts"
18
19AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003 Mark R. Shinwell"
20
21AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
22AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
23                   [Copyright Message for Aven])
24
25AC_SUBST(COPYRIGHT_MSG)
26AC_SUBST(AVEN_COPYRIGHT_MSG)
27
28dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
29PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
30AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
31                   [Name of package (capitalised)])
32AC_SUBST(PRETTYPACKAGE)
33
34dnl set COMMAVERSION to VERSION with the dots replaced by commas -
35dnl e.g. "0,99" or "1,0,22"
36COMMAVERSION=`echo "$VERSION"|tr '.' ','`
37AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
38                   [Version number of package (comma-separated)])
39AC_SUBST(COMMAVERSION)
40
41PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
42AC_ARG_ENABLE(docdir,
43[  --enable-docdir=DIR Set directory for installing documentation to DIR],
44[case $enableval in
45 yes|no)
46  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
47esac
48PKGDOCDIR="$enableval"
49]
50)
51PKGDOCDIR_EXPANDED=`(
52 test NONE = "$prefix" && prefix="$ac_default_prefix"
53 test NONE = "$exec_prefix" && exec_prefix="$prefix"
54 eval echo "$PKGDOCDIR"
55)`
56AC_SUBST(PKGDOCDIR)
57AC_SUBST(PKGDOCDIR_EXPANDED)
58
59DEFAULTLANG=en
60AC_ARG_ENABLE(defaultlang,
61[  --enable-defaultlang=LANG Set the default language for messages to LANG],
62[case $enableval in
63 yes|no) # until we support Norwegian...
64  AC_MSG_ERROR([configure: Syntax: configure --enable-defaultlang=LANGUAGE]) ;;
65esac
66DEFAULTLANG="$enableval"
67AC_DEFINE_UNQUOTED(DEFAULTLANG, [$enableval], [Default language for messages])
68]
69)
70AC_SUBST(DEFAULTLANG)
71
72AC_ARG_ENABLE(testprogs,
73[  --enable-testprogs Enable building of various test harness programs],
74[case $enableval in
75 yes) TESTPROGS="dump3d printxbm" ;;
76 no) TESTPROGS= ;;
77 *) AC_MSG_ERROR(bad value $enableval for --enable-testprogs) ;;
78esac
79]
80AC_SUBST(TESTPROGS)
81)
82
83AC_CANONICAL_HOST
84
85dnl Checks for programs.
86AC_PROG_CC
87AC_PROG_CPP
88
89AVEN='aven$(EXEEXT)'
90AC_ARG_ENABLE(aven,
91[  --disable-aven Don't try to build Aven cave viewer],
92[case $enableval in
93  yes) ;;
94  no) AVEN= ;;
95  *) AC_MSG_ERROR(bad value $enableval for --enable-aven) ;;
96esac])
97
98if test -n "$AVEN" ; then
99  AC_PROG_CXX
100  AC_PROG_CXXCPP
101else
102  dnl We don't want to fail to build Survex just because there's no C++
103  dnl compiler installed, so we need to invoke AC_PROG_CXX conditionally.
104  dnl This bodge is required in order to do that...
105  am__fastdepCXX_TRUE='#'
106  am__fastdepCXX_FALSE=
107fi
108
109AM_PROG_CC_C_O
110
111AC_LANG_C
112
113AC_PROG_MAKE_SET
114
115AC_EXEEXT
116AC_OBJEXT
117
118case $host_os in
119*mingw*|*cygwin*|windows*) mswindows=yes ;;
120*) mswindows=no ;;
121esac
122
123case $host in
124powerpc-*-darwin*) macosx=yes ;; # wxWidgets uses this to detect MacOS X
125*) macosx=no ;;
126esac
127
128AC_C_BIGENDIAN
129
130AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
131AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
132
133AC_CHECK_LIB(m, sqrt)
134
135AC_PATH_XTRA
136
137WINPROGS=
138if test yes = "$mswindows"; then
139  WINPROGS='printwin$(EXEEXT) editwrap$(EXEEXT)'
140  AC_MSG_RESULT(building printwin and editwrap)
141fi
142AC_SUBST(WINPROGS)
143
144AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
145AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
146: ${WX_CONFIG="$WXCONFIG"}
147
148if test yes = "$no_x"; then
149  AC_MSG_RESULT([not building xcaverot (X libraries not found or disabled)])
150  if test -z "$WX_CONFIG" && test no = "$mswindows"; then
151    AC_MSG_RESULT([not building aven (X libraries not found or disabled)])
152    AVEN=
153  fi
154else
155  AC_CHECK_LIB(Xext, XdbeQueryExtension, X_EXTRA_LIBS="-lXext $X_EXTRA_LIBS", ,
156               $X_LIBS $X_PRE_LIBS -lX11 -lXext $X_EXTRA_LIBS)
157  CAVEROT=xcaverot ${CAVEROT}
158  AC_MSG_RESULT(building xcaverot)
159fi
160
161AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
162AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
163
164if test -n "$AVEN"; then
165  if test -n "$WX_CONFIG" ; then
166    dnl WX_CONFIG specified - sanity check the value
167    dnl don't check for --ldflags - older wx-config didn't do that
168    if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags;exit $?) then
169      :
170    else
171      AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags' doesn't work, bailing out])
172    fi
173  else
174    # prefer wx2.6 or wx2.8 - a few things work better with it than with wx2.4.
175    if test yes = "$macosx" ; then
176      AC_PATH_PROGS(WX_CONFIG, [wxmac-2.8-config wxmac-2.6-config wxmac-2.4-config wxmac-config])
177      wxdef=__WXMAC__
178    elif test yes = "$mswindows" ; then
179      AC_PATH_PROGS(WX_CONFIG, [wxmsw-2.8-config wxmsw-2.6-config wxmsw-2.4-config wxmsw-config])
180      wxdef=__WXMSW__
181    else
182      AC_PATH_PROGS(WX_CONFIG, [wxgtk-2.8-config wxgtk-2.6-config wxgtk-2.4-config wxgtk-config])
183      wxdef=__WXGTK__
184    fi
185    if test -z "$WX_CONFIG" ; then
186      dnl see if wx-config exists and is for the correct version
187      AC_PATH_PROGS(WX_CONFIG, [wx-config])
188      if test -n "$WX_CONFIG" ; then
189        if (exec >&5 2>&5;$WX_CONFIG --cflags|grep -e -D"$wxdef";exit $?) then
190          :
191        else
192          WX_CONFIG=
193        fi
194      fi
195    fi
196    if test -z "$WX_CONFIG" ; then
197      AC_MSG_RESULT([not building aven (wxWidgets not found)])
198      AVEN=
199    fi
200  fi
201
202  if test -n "$AVEN"; then
203    WX_LIBS=`$WX_CONFIG --libs`
204    AC_SUBST(WX_LIBS)
205    dnl older wx-config didn't support this - error goes to stderr, with
206    dnl nothing to stdout, so just ignore stderr
207    WX_LDFLAGS=`$WX_CONFIG --ldflags 2> /dev/null`
208    AC_SUBST(WX_LDFLAGS)
209    WX_CFLAGS=`$WX_CONFIG --cflags`
210    AC_SUBST(WX_CFLAGS)
211    WX_CXXFLAGS=`$WX_CONFIG --cxxflags`
212    AC_SUBST(WX_CXXFLAGS)
213    AC_MSG_RESULT(building aven)
214  fi
215fi
216
217AM_CONDITIONAL(AVEN, [test -n "$AVEN"])
218
219AC_LANG_C
220
221AC_SUBST(CAVEROT)
222AC_SUBST(AVEN)
223
224dnl only build extra man pages on Unix - the ".exe" messes us up otherwise
225dnl FIXME: probably no point building man pages except on Unix
226if test -z "$ac_exeext" ; then
227  dnl can't use \> as freebsd sed doesn't support it
228  EXTRA_MANS=`echo "$CAVEROT $AVEN"|sed 's/\$(EXEEXT)//g;s/\([[^ ]]\) /\1.1 /g;s/\(.\)$/\1.1/'`
229else
230  EXTRA_MANS=
231fi
232AC_SUBST(EXTRA_MANS)
233
234dnl caverot libraries...
235AC_SUBST(CRLIB)
236dnl caverot platform specific sources...
237AC_SUBST(CROBJX)
238
239dnl Checks for header files.
240AC_HEADER_STDC
241dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
242AC_CHECK_HEADERS(limits.h string.h setjmp.h)
243
244dnl Checks for typedefs, structures, and compiler characteristics.
245AC_C_CONST
246AC_TYPE_SIZE_T
247AC_STRUCT_TM
248AC_TYPE_SIGNAL
249
250dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
251dnl if it isn't, assume it is 1000000, as it is on SunOS 4
252AC_TRY_COMPILE([#include <time.h>],[
253#ifndef CLOCKS_PER_SEC
254choke me
255#endif
256], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
257
258dnl Look for a signed 32 bit integer type
259AC_MSG_CHECKING(for 32 bit integer type)
260AC_TRY_COMPILE(,[switch (0) { case (sizeof(int)==4): case 0: break; }],
261INT32_T=int,
262AC_TRY_COMPILE(,[switch (0) { case (sizeof(long)==4): case 0: break; }],
263INT32_T=long,
264AC_MSG_ERROR(not found)
265)
266)
267AC_MSG_RESULT($INT32_T)
268AC_DEFINE_UNQUOTED(INT32_T,$INT32_T,[signed 32 bit integer type])
269
270dnl Look for a signed 16 bit integer type
271AC_MSG_CHECKING(for 16 bit integer type)
272AC_TRY_COMPILE(,[switch (0) { case (sizeof(short)==2): case 0: break; }],
273INT16_T=short,
274AC_TRY_COMPILE(,[switch (0) { case (sizeof(int)==2): case 0: break; }],
275INT16_T=int,
276AC_MSG_ERROR(not found)
277)
278)
279AC_MSG_RESULT($INT16_T)
280AC_DEFINE_UNQUOTED(INT16_T,$INT16_T,[signed 16 bit integer type])
281
282dnl Checks for library functions.
283AC_FUNC_STRFTIME
284if test yes != "$ac_cv_func_strftime"; then
285  AC_LIBOBJ(strftime)
286fi
287AC_FUNC_VPRINTF
288dnl check for strcasecmp here as well as below - this one is to get
289dnl HAVE_STRCASECMP defined if appropriate (for img.c)
290AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot)
291
292dnl difftime seems to be an ANSI invention
293AC_CHECK_FUNCS(difftime)
294
295dnl Much faster than using getc()/putc(), at least on Linux.
296AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
297
298dnl try to find a case-insensitive compare
299
300strcasecmp=no
301dnl The order of these tests is important.
302AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
303if test no = "$strcasecmp"; then
304  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
305fi
306if test no = "$strcasecmp"; then
307  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
308fi
309
310AC_MSG_CHECKING([how to compare strings ignoring case])
311case $strcasecmp in
312no)
313  AC_LIBOBJ(strcasecmp)
314  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
315strcasecmp)
316  AC_MSG_RESULT([strcasecmp]) ;;
317*)
318  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
319    [strcasecmp define for systems which call it something else])
320  AC_MSG_RESULT([$strcasecmp]) ;;
321esac
322
323AC_MSG_CHECKING(for sgmltools v2 or v3)
324case `(exec 2>&5 ; sgmltools --version)` in
325*" version 2"*)
326  sgmltools=sgmltools
327  AC_MSG_RESULT(yes) ;;
328*" version 3"*)
329  sgmltools=sgmltools
330  AC_MSG_RESULT(yes) ;;
331*)
332  sgmltools="$MISSING sgmltools"
333  AC_MSG_RESULT(no) ;;
334esac
335AC_SUBST(sgmltools)
336
337dnl extra warning flags for building with GCC
338if test yes = "$GCC"; then
339  if test yes = "$cross_compiling"; then
340    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
341      -Wwrite-strings -Wcast-align"
342    AM_CXXFLAGS="$AM_CXXFLAGS -Werror -Wall -Wunused -Wpointer-arith\
343      -Wwrite-strings -Wcast-align"
344  else
345    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
346      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
347      -Wcast-align"
348    dnl -W causes problems with wxWidgets
349    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wshadow -Wpointer-arith\
350      -Wwrite-strings -Wcast-align"
351  fi
352  dnl too many complaints from headers, etc: -Wconversion
353fi
354AC_SUBST(AM_CFLAGS)
355AC_SUBST(AM_CXXFLAGS)
356
357AC_ARG_ENABLE(profiling,
358[  --enable-profiling Build binaries to generate profiling information],
359[case $enableval in
360  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
361       AM_CFLAGS="$AM_CFLAGS -pg"
362       AC_MSG_RESULT(building binaries to generate profiling information);;
363  no) ;;
364  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
365esac])
366
367DOCS_OTHER="manual.rtf manual.txt manual.ps"
368AC_SUBST(DOCS_OTHER)
369
370HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm"
371AC_SUBST(HTMLFILES)
372
373EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
374AC_SUBST(EXTRA_TEXT)
375
376AC_SUBST_FILE(DESC)
377DESC=desc.txt
378AC_SUBST_FILE(AVENDESC)
379AVENDESC=desc-aven.txt
380AC_SUBST_FILE(SVXEDITDESC)
381SVXEDITDESC=desc-svxedit.txt
382
383dnl Don't define DATADIR if building for MS Windows - it won't be used, and
384dnl can conflict with the DATADIR typedef in objidl.h
385if test no = "$mswindows"; then
386  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
387fi
388
389AH_BOTTOM(
390[/* Use getc_unlocked() and putc_unlocked() where available, since they are
391 * faster, and we don't multithread file accesses.
392 */
393
394#ifdef HAVE_GETC_UNLOCKED
395# define GETC(F) getc_unlocked(F)
396#else
397# define GETC(F) getc(F)
398#endif
399#ifdef HAVE_PUTC_UNLOCKED
400# define PUTC(C, F) putc_unlocked(C, F)
401#else
402# define PUTC(C, F) putc(C, F)
403#endif
404])
405
406AC_OUTPUT(Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
407 tests/Makefile debian/Makefile survex.iss doc/index.htm doc/survex.1
408 src/borlandc/config.h src/riscos/config.h src/msvc/config.h
409 doc/version.ent debian/copyright survex.spec src/svxedit lib/survex.keys)
Note: See TracBrowser for help on using the repository browser.