source: git/configure.ac @ a6ff0d4

stereo-2025warn-only-for-hanging-survey
Last change on this file since a6ff0d4 was f31090c, checked in by Olly Betts <olly@…>, 13 months ago

Remove lingering traces of use of wxHtmlWindow

  • Property mode set to 100644
File size: 11.5 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.4.8], [https://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2024 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`(
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59)`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_CANONICAL_HOST
64
65dnl Checks for programs.
66AC_PROG_CC
67AC_PROG_CPP
68
69AC_PROG_CXX
70AC_PROG_CXXCPP
71
72dnl Probe for any options needed to enable C++11 support.
73AX_CXX_COMPILE_STDCXX_11
74
75AM_PROG_CC_C_O
76
77AC_LANG([C])
78
79AC_EXEEXT
80AC_OBJEXT
81
82mswindows=no
83macos=no
84case $host_os in
85darwin*) macos=yes ;;
86*mingw*|*cygwin*|windows*) mswindows=yes ;;
87esac
88
89AC_C_BIGENDIAN
90
91AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
92AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
93
94AC_CHECK_LIB(m, sqrt)
95
96AC_PATH_XTRA
97
98dnl The wxWidgets libraries we need:
99wx_libs="core,gl"
100
101AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
102AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
103: ${WX_CONFIG="$WXCONFIG"}
104
105AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
106AM_CONDITIONAL(MACOS, [test yes = "$macos"])
107
108if test -n "$WX_CONFIG" ; then
109  dnl WX_CONFIG specified - sanity check the value
110  dnl don't check for --ldflags - older wx-config didn't do that
111  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
112    :
113  else
114    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
115  fi
116else
117  if test yes = "$macos" ; then
118    wxdef=__WXMAC__
119  elif test yes = "$mswindows" ; then
120    wxdef=__WXMSW__
121  else
122    wxdef=__WXGTK__
123  fi
124  dnl See if wx-config exists and is for the correct version.
125  dnl Fedora install wx3's wx-config as wx-config-3.0, so look for that in
126  dnl preference.
127  dnl Arch Linux uses wx-config-gtk3.
128  AC_PATH_PROGS(WX_CONFIG, [wx-config-3.0 wx-config-gtk3 wx-config])
129  if test -n "$WX_CONFIG" ; then
130    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
131      :
132    else
133      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
134    fi
135  else
136    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
137  fi
138fi
139
140dnl Unless the user has explicitly specified a --unicode setting, prefer
141dnl --unicode=yes if we can get it.
142case $WX_CONFIG in
143  *--unicode=*) ;;
144  *)
145    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
146      WX_CONFIG="$WX_CONFIG --unicode=yes"
147    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
148      WX_CONFIG="$WX_CONFIG --unicode=no"
149    fi ;;
150esac
151
152WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
153dnl Needed for nvidia drivers on linux (for some setups anyway).
154AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
155dnl We use functions from libGLU so always link -lGLU explicitly if it's
156dnl present.
157AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
158dnl We use functions from libGL so always link -lGL explicitly if it's
159dnl present.
160AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
161AC_SUBST(WX_LIBS)
162dnl macOS has OpenGL/gl.h.
163AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
164dnl The Debian mingw-w64 packages lack GL/glext.h; macOS has OpenGL/glext.h.
165AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
166
167WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
168AC_SUBST(WX_CFLAGS)
169WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
170AC_SUBST(WX_CXXFLAGS)
171
172AC_LANG([C])
173save_CFLAGS=$CFLAGS
174CFLAGS="$CFLAGS $WX_CFLAGS"
175AC_CHECK_SIZEOF([wxChar], [], [
176  #include <wx/defs.h>
177  #include <wx/chartype.h>
178])
179CFLAGS=$save_CFLAGS
180
181dnl Check for FFmpeg libraries.
182PKG_CHECK_MODULES([FFMPEG], [libavcodec libavformat libswscale libavutil], [
183  AC_DEFINE([WITH_FFMPEG], [1], [Use FFmpeg for movie export])
184  save_CXXFLAGS=$CXXFLAGS
185  save_LIBS=$LIBS
186  CFLAGS="$CFLAGS $FFMPEG_CFLAGS"
187  LIBS="$LIBS $FFMPEG_LIBS"
188  AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_free_frame avcodec_open2 avformat_new_stream av_frame_alloc av_frame_free])
189  AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
190  AC_CHECK_DECLS([AV_CODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
191  AC_CHECK_DECLS([AV_PIX_FMT_RGB24], [], [], [#include <libavutil/pixfmt.h>])
192  AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
193  CXXFLAGS=$save_CXXFLAGS
194  LIBS=$save_LIBS
195], [
196  dnl Build without movie export feature.
197])
198AC_SUBST([FFMPEG_LIBS])
199AC_SUBST([FFMPEG_CFLAGS])
200
201dnl Check for PROJ.
202PKG_CHECK_MODULES([PROJ], [proj >= 6.2.0], [
203], [
204  dnl pkg-config support in proj seems quite new, so probe directly if not
205  dnl found.  We need proj_create_crs_to_crs_from_pj() which was added in
206  dnl 6.2.0.
207  AC_CHECK_LIB([proj], [proj_create_crs_to_crs_from_pj], [
208      PROJ_LIBS=-lproj
209      PROJ_CFLAGS=
210    ], [
211      AC_MSG_ERROR([PROJ required for coordinate transformations])
212    ])
213])
214AC_SUBST([PROJ_LIBS])
215AC_SUBST([PROJ_CFLAGS])
216
217dnl Check for GDAL.
218PKG_CHECK_MODULES([GDAL], [gdal >= 2.3], [
219], [
220  AC_MSG_ERROR([GDAL required for geodata handling])
221])
222AC_SUBST([GDAL_LIBS])
223AC_SUBST([GDAL_CFLAGS])
224
225dnl Checks for header files.
226
227dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
228AC_CHECK_HEADERS(limits.h string.h setjmp.h)
229
230dnl Checks for typedefs, structures, and compiler characteristics.
231AC_TYPE_SIZE_T
232AC_STRUCT_TM
233
234dnl Check for 16-bit and 32-bit integer types.
235AC_TYPE_INT16_T
236AC_TYPE_UINT16_T
237AC_TYPE_INT32_T
238AC_TYPE_UINT32_T
239
240dnl Check if there's a declaration of lround().  Below we also check for
241dnl lround() with AC_CHECK_FUNCS, which just checks if it can be linked
242dnl against.  Some platforms are missing a prototype for lround(), so
243dnl both checks are useful.
244AC_CHECK_DECLS([lround], [], [], [[#include <math.h>]])
245AC_CHECK_FUNCS([popen getpwuid lround hypot mmap])
246
247dnl Much faster than using getc()/putc(), at least on Linux.
248AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
249
250AC_CHECK_FUNCS([setenv unsetenv])
251
252AC_CHECK_FUNCS([fmemopen])
253
254AC_PATH_PROG([JW], [jw], [$MISSING jw])
255AC_ARG_VAR([JW], [jw from docbook-utils/docbook-tools])
256
257AC_PATH_PROG([MSGFMT], [msgfmt], [$MISSING msgfmt])
258AC_ARG_VAR([MSGFMT], [msgfmt from gettext])
259
260AC_ARG_ENABLE([werror],
261  [AS_HELP_STRING([--enable-werror], [enable treating compiler warnings as errors [default=no]])],
262  [case ${enableval} in
263    yes|no) ;;
264  *) AC_MSG_ERROR([bad value ${enableval} for --enable-werror]) ;;
265  esac],
266  [enable_werror=no])
267
268dnl Put -Werror or equivalent in its own make variable so that it can easily
269dnl be overridden by `make WERROR=` if needed during development (e.g. if
270dnl you want to get a full list of compile warnings to fix rather than
271dnl stopping at the first file with warnings).
272WERROR=
273AC_SUBST([WERROR])
274
275dnl extra warning flags for building with GCC
276if test yes = "$GCC"; then
277  WERROR=-Werror
278  if test yes = "$cross_compiling"; then
279dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
280dnl      -Wwrite-strings -Wcast-align"
281dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
282dnl to disable it for mingw builds.
283    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
284      -Wwrite-strings -Wcast-align"
285    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
286      -Wwrite-strings -Wcast-align -Wno-sign-compare"
287  else
288    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
289      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
290      -Wcast-align"
291    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
292      -Wwrite-strings -Wcast-align"
293  fi
294  dnl too many complaints from headers, etc: -Wconversion
295fi
296AC_SUBST(AM_CFLAGS)
297AC_SUBST(AM_CXXFLAGS)
298
299if test x$enable_werror != xyes; then
300  WERROR=
301fi
302
303dnl See if large file support is available.  Survex is unlikely to need to
304dnl process files > 2GB in size, but LFS is also needed for stat() to work
305dnl on filing systems which return 64 bit inode values, such as CIFS mounts.
306AC_SYS_LARGEFILE
307
308AC_ARG_ENABLE(profiling,
309[  --enable-profiling Build binaries to generate profiling information],
310[case $enableval in
311  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
312       AM_CFLAGS="$AM_CFLAGS -pg"
313       AC_MSG_RESULT(building binaries to generate profiling information);;
314  no) ;;
315  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
316esac])
317
318HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
319AC_SUBST(HTMLFILES)
320
321EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
322AC_SUBST(EXTRA_TEXT)
323
324AC_SUBST_FILE(DESC)
325DESC=desc.txt
326AC_SUBST_FILE(AVENDESC)
327AVENDESC=desc-aven.txt
328
329dnl Don't define DATADIR if building for MS Windows - it won't be used, and
330dnl can conflict with the DATADIR typedef in objidl.h
331if test no = "$mswindows"; then
332  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
333fi
334
335AH_BOTTOM(
336[/* Use getc_unlocked() and putc_unlocked() where available, since they are
337 * faster, and we don't multithread file accesses.
338 */
339
340#ifdef HAVE_GETC_UNLOCKED
341# define GETC(F) getc_unlocked(F)
342#else
343# define GETC(F) getc(F)
344#endif
345#ifdef HAVE_PUTC_UNLOCKED
346# define PUTC(C, F) putc_unlocked(C, F)
347#else
348# define PUTC(C, F) putc(C, F)
349#endif
350
351#ifndef __cplusplus
352/* C23 added bool, false and true as keywords - let's emulate that and
353 * avoid every C file which uses these needing to include <stdbool.h>.
354 */
355# include <stdbool.h>
356#endif
357])
358
359AC_CONFIG_FILES([
360 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
361 lib/images/Makefile
362 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
363 survex.spec lib/Info.plist
364 ])
365AC_OUTPUT
366dnl FIXME update msvc makefile for 1.2 branch
367dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.