source: git/configure.ac @ 64d06c0

RELEASE/1.2debug-cidebug-ci-sanitisersstereowalls-data
Last change on this file since 64d06c0 was 64d06c0, checked in by Olly Betts <olly@…>, 11 years ago

configure.ac,src/moviemaker.cc,src/moviemaker.h: Update movie export
code to work with latest libav API.

  • Property mode set to 100644
File size: 12.0 KB
Line 
1dnl Process this file with autoconf to produce a configure script
2
3dnl Need autoconf 2.50 or later for AC_ARG_VAR.  2.59 has been around for
4dnl long enough, that we might as well just require that.
5AC_PREREQ(2.59)
6AC_INIT([survex], [1.2.7], [http://trac.survex.com/])
7AM_INIT_AUTOMAKE([1.5 gnu -Wall -Wportability -Werror])
8RELEASE=1
9
10AC_SUBST(RELEASE)
11AC_CONFIG_HEADERS([config.h])
12AC_CONFIG_SRCDIR([src/aven.cc])
13
14COPYRIGHT_MSG="Copyright (C) 1990-2013 Olly Betts"
15AVEN_COPYRIGHT_MSG="Copyright (C) 1999-2003,2005,2006 Mark R. Shinwell"
16
17AC_DEFINE_UNQUOTED(COPYRIGHT_MSG, ["$COPYRIGHT_MSG"], [Copyright Message])
18AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG, ["$AVEN_COPYRIGHT_MSG"],
19                   [Copyright Message for Aven])
20
21AC_SUBST(COPYRIGHT_MSG)
22AC_SUBST(AVEN_COPYRIGHT_MSG)
23
24COPYRIGHT_MSG_UTF8=`echo "$COPYRIGHT_MSG"|sed 's/(C)/©/'`
25AVEN_COPYRIGHT_MSG_UTF8=`echo "$AVEN_COPYRIGHT_MSG"|sed 's/(C)/©/'`
26
27AC_DEFINE_UNQUOTED(COPYRIGHT_MSG_UTF8, ["$COPYRIGHT_MSG_UTF8"],
28                   [Copyright Message in UTF-8])
29AC_DEFINE_UNQUOTED(AVEN_COPYRIGHT_MSG_UTF8, ["$AVEN_COPYRIGHT_MSG_UTF8"],
30                   [Copyright Message for Aven in UTF-8])
31
32dnl set PRETTYPACKAGE to PACKAGE with the first character capitalised
33PRETTYPACKAGE=`echo "$PACKAGE"|cut -b1|tr a-z A-Z``echo "$PACKAGE"|cut -b2-`
34AC_DEFINE_UNQUOTED(PRETTYPACKAGE, "$PRETTYPACKAGE",
35                   [Name of package (capitalised)])
36AC_SUBST(PRETTYPACKAGE)
37
38dnl set COMMAVERSION to VERSION with the dots replaced by commas -
39dnl e.g. "0,99" or "1,0,22"
40COMMAVERSION=`echo "$VERSION"|tr '.' ','`
41AC_DEFINE_UNQUOTED(COMMAVERSION, $COMMAVERSION,
42                   [Version number of package (comma-separated)])
43AC_SUBST(COMMAVERSION)
44
45PKGDOCDIR='${prefix}/share/doc/${PACKAGE}'
46AC_ARG_ENABLE(docdir,
47[  --enable-docdir=DIR Set directory for installing documentation to DIR],
48[case $enableval in
49 yes|no)
50  AC_MSG_ERROR([configure: Syntax: configure --enable-docdir=DIR]) ;;
51esac
52PKGDOCDIR="$enableval"
53]
54)
55PKGDOCDIR_EXPANDED=`(
56 test NONE = "$prefix" && prefix="$ac_default_prefix"
57 test NONE = "$exec_prefix" && exec_prefix="$prefix"
58 eval echo "$PKGDOCDIR"
59)`
60AC_SUBST(PKGDOCDIR)
61AC_SUBST(PKGDOCDIR_EXPANDED)
62
63AC_CANONICAL_HOST
64
65dnl Checks for programs.
66AC_PROG_CC
67AC_PROG_CPP
68
69AC_PROG_CXX
70AC_PROG_CXXCPP
71
72AM_PROG_CC_C_O
73
74AC_LANG_C
75
76AC_C_INLINE
77
78AC_EXEEXT
79AC_OBJEXT
80
81mswindows=no
82macosx=no
83case $host_os in
84darwin*) macosx=yes ;;
85*mingw*|*cygwin*|windows*) mswindows=yes ;;
86esac
87
88AC_C_BIGENDIAN
89
90AC_ARG_VAR(STRIP, [Command for discarding symbols from object files])
91AC_PATH_TOOL(STRIP, strip, [echo "not stripping "])
92
93AC_CHECK_LIB(m, sqrt)
94
95AC_PATH_XTRA
96
97WINPROGS=
98if test yes = "$mswindows"; then
99  WINPROGS='editwrap$(EXEEXT)'
100  AC_MSG_RESULT(building editwrap)
101fi
102AC_SUBST(WINPROGS)
103
104dnl The wxWidgets libraries we need:
105wx_libs="core,gl,html"
106
107AC_ARG_VAR(WXCONFIG, [Old name for WX_CONFIG, accepted for compatibility])
108AC_ARG_VAR(WX_CONFIG, [wxWidgets configuration script to use to build Aven])
109: ${WX_CONFIG="$WXCONFIG"}
110
111AM_CONDITIONAL(WIN32, [test yes = "$mswindows"])
112AM_CONDITIONAL(MACOSX, [test yes = "$macosx"])
113
114if test -n "$WX_CONFIG" ; then
115  dnl WX_CONFIG specified - sanity check the value
116  dnl don't check for --ldflags - older wx-config didn't do that
117  if (exec >&5 2>&5;$WX_CONFIG --libs --cflags --cxxflags "$wx_libs";exit $?) then
118    :
119  else
120    AC_MSG_ERROR(['$WX_CONFIG --libs --cflags --cxxflags "$wx_libs"' does not work, bailing out])
121  fi
122else
123  if test yes = "$macosx" ; then
124    wxdef=__WXMAC__
125  elif test yes = "$mswindows" ; then
126    wxdef=__WXMSW__
127  else
128    wxdef=__WXGTK__
129  fi
130  dnl See if wx-config exists and is for the correct version.
131  AC_PATH_PROGS(WX_CONFIG, [wx-config])
132  if test -n "$WX_CONFIG" ; then
133    if (exec >&5 2>&5;$WX_CONFIG --cflags "$wx_libs"|grep -e -D"$wxdef";exit $?) then
134      :
135    else
136      AC_MSG_ERROR([wxWidgets not for the right toolkit.  Run ./configure WX_CONFIG=/path/to/wx-config])
137    fi
138  else
139    AC_MSG_ERROR([wxWidgets not found.  Run ./configure WX_CONFIG=/path/to/wx-config])
140  fi
141fi
142
143dnl Unless the user has explicitly specified a --unicode setting, prefer
144dnl --unicode=yes if we can get it.
145case $WX_CONFIG in
146  *--unicode=*) ;;
147  *)
148    if (exec >&5 2>&5;$WX_CONFIG --unicode=yes --version "$wx_libs";exit $?) ; then
149      WX_CONFIG="$WX_CONFIG --unicode=yes"
150    elif (exec >&5 2>&5;$WX_CONFIG --unicode=no --version "$wx_libs";exit $?) ; then
151      WX_CONFIG="$WX_CONFIG --unicode=no"
152    fi ;;
153esac
154
155WX_LIBS=`$WX_CONFIG --libs "$wx_libs"`
156dnl Needed for nvidia drivers on linux (for some setups anyway).
157AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryVersion, [WX_LIBS="$WX_LIBS -lXxf86vm"], [], [$WX_LIBS])
158dnl We use functions from libGLU so always link -lGLU explicitly if it's
159dnl present.
160AC_CHECK_LIB([GLU], [gluProject], [WX_LIBS="$WX_LIBS -lGLU"], [], [$WX_LIBS])
161dnl We use functions from libGL so always link -lGL explicitly if it's
162dnl present.
163AC_CHECK_LIB([GL], [glPushMatrix], [WX_LIBS="$WX_LIBS -lGL"], [], [$WX_LIBS])
164AC_SUBST(WX_LIBS)
165dnl Mac OS X has OpenGL/gl.h.
166AC_CHECK_HEADERS([GL/gl.h OpenGL/gl.h], [], [], [ ])
167dnl The Debian mingw-w64 packages lack GL/glext.h; Mac OS X has OpenGL/glext.h.
168AC_CHECK_HEADERS([GL/glext.h OpenGL/glext.h], [], [], [#include <GL/gl.h>])
169
170dnl Older wx-config didn't support --ldflags (2.6.3 doesn't) - error goes to
171dnl stderr, with nothing to stdout, so just ignore stderr.
172WX_LDFLAGS=`$WX_CONFIG --ldflags "$wx_libs" 2> /dev/null`
173AC_SUBST(WX_LDFLAGS)
174WX_CFLAGS=`$WX_CONFIG --cflags "$wx_libs"`
175AC_SUBST(WX_CFLAGS)
176WX_CXXFLAGS=`$WX_CONFIG --cxxflags "$wx_libs"`
177AC_SUBST(WX_CXXFLAGS)
178
179AC_LANG_C
180save_CFLAGS=$CFLAGS
181CFLAGS="$CFLAGS $WX_CFLAGS"
182AC_CHECK_SIZEOF([wxChar], [], [
183  #include <wx/defs.h>
184  #if wxCHECK_VERSION(2,9,0)
185  #include <wx/chartype.h>
186  #else
187  #include <wx/wxchar.h>
188  #endif
189])
190CFLAGS=$save_CFLAGS
191
192AVEN_LIBS=
193AC_SUBST(AVEN_LIBS)
194
195dnl Check for ffmpeg
196AC_CHECK_LIB(avcodec, avcodec_register_all,
197  [AC_CHECK_LIB(avformat, av_register_all,
198    [AC_CHECK_LIB(swscale, sws_scale,
199      [AC_CHECK_LIB(avutil, av_malloc,
200        [AC_CHECK_HEADERS([libavformat/avformat.h],
201          [AVEN_LIBS="-lswscale -lavformat -lavcodec -lavutil"
202          save_LIBS=$LIBS
203          LIBS="$LIBS $AVEN_LIBS"
204          AC_CHECK_FUNCS([av_guess_format avio_open avio_close avformat_write_header avcodec_encode_video2 avcodec_open2 avformat_new_stream])
205          AC_CHECK_DECLS([AVMEDIA_TYPE_VIDEO], [], [], [#include <libavcodec/avcodec.h>])
206          AC_CHECK_DECLS([AVCODEC_ID_NONE], [], [], [#include <libavcodec/avcodec.h>])
207          AC_CHECK_DECLS([AV_PIX_FMT_YUV420P], [], [], [#include <libavutil/pixfmt.h>])
208          LIBS=$save_LIBS])],
209        [], [-lavformat -lavcodec -lswscale $WX_LIBS])],
210      [], [-lavformat -lavcodec $WX_LIBS])],
211    [], [-lavcodec $WX_LIBS])
212])
213
214dnl Check for libproj
215AC_CHECK_LIB([proj], [pj_init_plus], [AVEN_LIBS="$AVEN_LIBS -lproj"])
216
217dnl Checks for header files.
218AC_HEADER_STDC
219dnl don't use AC_CHECK_FUNCS for setjmp - mingw #define-s it to _setjmp
220AC_CHECK_HEADERS(limits.h string.h setjmp.h sys/select.h)
221
222dnl Checks for typedefs, structures, and compiler characteristics.
223AC_C_CONST
224AC_TYPE_SIZE_T
225AC_STRUCT_TM
226AC_TYPE_SIGNAL
227
228dnl check if CLOCKS_PER_SEC is defined by time.h (as ANSI says it should be)
229dnl if it isn't, assume it is 1000000, as it is on SunOS 4
230AC_TRY_COMPILE([#include <time.h>],[
231#ifndef CLOCKS_PER_SEC
232choke me
233#endif
234], , AC_DEFINE(CLOCKS_PER_SEC, 1000000, [For old systems which don't define it themselves]))
235
236dnl Check for 16-bit and 32-bit integer types.
237AC_TYPE_INT16_T
238AC_TYPE_INT32_T
239
240dnl Checks for library functions.
241AC_FUNC_STRFTIME
242if test yes != "$ac_cv_func_strftime"; then
243  AC_LIBOBJ(strftime)
244fi
245AC_FUNC_VPRINTF
246dnl Check if there's a declaration of round().  Below we also check for
247dnl round() with AC_CHECK_FUNCS, which just checks if it can be linked
248dnl against.  Some platforms are missing a prototype for round(), so
249dnl both checks are useful.
250AC_CHECK_DECLS([round], [], [], [[#include <math.h>]])
251dnl check for strcasecmp here as well as below - this one is to get
252dnl HAVE_STRCASECMP defined if appropriate (for img.c)
253AC_CHECK_FUNCS(popen signal getpwuid round strcasecmp hypot lstat)
254
255dnl difftime seems to be an ANSI invention
256AC_CHECK_FUNCS(difftime)
257
258dnl Much faster than using getc()/putc(), at least on Linux.
259AC_CHECK_FUNCS([getc_unlocked putc_unlocked])
260
261dnl try to find a case-insensitive compare
262
263strcasecmp=no
264dnl The order of these tests is important.
265AC_CHECK_FUNC(strcasecmp, [strcasecmp=strcasecmp])
266if test no = "$strcasecmp"; then
267  AC_CHECK_FUNC(stricmp, [strcasecmp=stricmp])
268fi
269if test no = "$strcasecmp"; then
270  AC_CHECK_FUNC(strcmpi, [strcasecmp=strcmpi])
271fi
272
273AC_MSG_CHECKING([how to compare strings ignoring case])
274case $strcasecmp in
275no)
276  AC_LIBOBJ(strcasecmp)
277  AC_MSG_RESULT([using own implementation of strcasecmp]) ;;
278strcasecmp)
279  AC_MSG_RESULT([strcasecmp]) ;;
280*)
281  AC_DEFINE_UNQUOTED(strcasecmp, "$strcasecmp",
282    [strcasecmp define for systems which call it something else])
283  AC_MSG_RESULT([$strcasecmp]) ;;
284esac
285
286AC_MSG_CHECKING(for sgmltools v2 or v3)
287if test : != "$SGMLTOOLS" ; then
288  : ${SGMLTOOLS=sgmltools}
289  case `(exec 2>&5 ; $SGMLTOOLS --version)` in
290  *" version 3"*)
291    AC_MSG_RESULT([$SGMLTOOLS]) ;;
292  *" version 2"*)
293    AC_MSG_RESULT([$SGMLTOOLS]) ;;
294  *)
295    SGMLTOOLS="$MISSING sgmltools"
296    AC_MSG_RESULT(not found) ;;
297  esac
298else
299  AC_MSG_RESULT([$SGMLTOOLS])
300fi
301AC_SUBST(SGMLTOOLS)
302AC_ARG_VAR(SGMLTOOLS, [sgmltools command])
303
304AC_MSG_CHECKING(for docbook-to-man)
305if test : != "$DOCBOOK_TO_MAN" ; then
306  : ${DOCBOOK_TO_MAN=docbook-to-man}
307  $DOCBOOK_TO_MAN 2> /dev/null
308  if test $? = 1 ; then
309    AC_MSG_RESULT([$DOCBOOK_TO_MAN])
310  else
311    DOCBOOK_TO_MAN="$MISSING docbook-to-man"
312    AC_MSG_RESULT([not found])
313  fi
314else
315  AC_MSG_RESULT([$DOCBOOK_TO_MAN])
316fi
317AC_SUBST(DOCBOOK_TO_MAN)
318AC_ARG_VAR(DOCBOOK_TO_MAN, [docbook-to-man command])
319
320dnl extra warning flags for building with GCC
321if test yes = "$GCC"; then
322  if test yes = "$cross_compiling"; then
323dnl    AM_CFLAGS="$AM_CFLAGS -Werror -Wall -Wunused -Wpointer-arith\
324dnl      -Wwrite-strings -Wcast-align"
325dnl -Wsign-compare causes a warning with the mingw FD_SET macro, so we have
326dnl to disable it for mingw builds.
327    AM_CFLAGS="$AM_CFLAGS -Wall -Wunused -Wpointer-arith\
328      -Wwrite-strings -Wcast-align"
329    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -Wunused -Wpointer-arith\
330      -Wwrite-strings -Wcast-align -Wno-sign-compare"
331  else
332    AM_CFLAGS="$AM_CFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
333      -Wmissing-prototypes -Wwrite-strings -Wredundant-decls -Wnested-externs\
334      -Wcast-align"
335    AM_CXXFLAGS="$AM_CXXFLAGS -Wall -W -Wunused -Wshadow -Wpointer-arith\
336      -Wwrite-strings -Wcast-align"
337  fi
338  dnl too many complaints from headers, etc: -Wconversion
339fi
340AC_SUBST(AM_CFLAGS)
341AC_SUBST(AM_CXXFLAGS)
342
343AC_ARG_ENABLE(profiling,
344[  --enable-profiling Build binaries to generate profiling information],
345[case $enableval in
346  yes) AM_CXXFLAGS="$AM_CXXFLAGS -pg"
347       AM_CFLAGS="$AM_CFLAGS -pg"
348       AC_MSG_RESULT(building binaries to generate profiling information);;
349  no) ;;
350  *) AC_MSG_ERROR(bad value $enableval for --enable-profiling) ;;
351esac])
352
353HTMLFILES="AUTHORS.htm HACKING.htm NEWS.htm OLDNEWS.htm TODO.htm index.htm 3dformat.htm 3dformat-old.htm"
354AC_SUBST(HTMLFILES)
355
356EXTRA_TEXT="AUTHORS COPYING NEWS TODO ChangeLog"
357AC_SUBST(EXTRA_TEXT)
358
359AC_SUBST_FILE(DESC)
360DESC=desc.txt
361AC_SUBST_FILE(AVENDESC)
362AVENDESC=desc-aven.txt
363AC_SUBST_FILE(SVXEDITDESC)
364SVXEDITDESC=desc-svxedit.txt
365
366dnl Don't define DATADIR if building for MS Windows - it won't be used, and
367dnl can conflict with the DATADIR typedef in objidl.h
368if test no = "$mswindows"; then
369  AC_DEFINE_DIR(DATADIR, datadir, [Location of platform independent support files])
370fi
371
372AH_BOTTOM(
373[/* Use getc_unlocked() and putc_unlocked() where available, since they are
374 * faster, and we don't multithread file accesses.
375 */
376
377#ifdef HAVE_GETC_UNLOCKED
378# define GETC(F) getc_unlocked(F)
379#else
380# define GETC(F) getc(F)
381#endif
382#ifdef HAVE_PUTC_UNLOCKED
383# define PUTC(C, F) putc_unlocked(C, F)
384#else
385# define PUTC(C, F) putc(C, F)
386#endif
387])
388
389AC_CONFIG_FILES([
390 Makefile src/Makefile doc/Makefile lib/Makefile lib/icons/Makefile
391 tests/Makefile vim/Makefile survex.iss doc/index.htm doc/survex.7
392 doc/version.ent survex.spec src/svxedit lib/survex.keys lib/Info.plist
393 ])
394AC_OUTPUT
395dnl FIXME update msvc makefile for 1.1 branch
396dnl src/msvc/config.h
Note: See TracBrowser for help on using the repository browser.